net-irc/kvirc: update, unlastrite, take

Closes: https://bugs.gentoo.org/905955
Signed-off-by: Alexey Sokolov <alexey+gentoo@asokolov.org>
Closes: https://github.com/gentoo/gentoo/pull/31071
Signed-off-by: Sam James <sam@gentoo.org>

5 files changed, 189 insertions, 6 deletions

diff --git a/net-irc/kvirc/Manifest b/net-irc/kvirc/Manifest
index b20a302e1243..3f6d1ad09ee2 100644
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1 +1,2 @@
 DIST kvirc-5.2_pre20210630233331.tar.gz 6173417 BLAKE2B dcdb5fed3250de08d8e2896ba799e142ee04fff409006d7b7d06bdcf1cf2f6df9f7abeeb055e550d99f9cca6182d68b4f5b9ff224f78d91b1efb7f42118458e5 SHA512 625712cc69a2ab3a33b72b2e9935bec8f307ef1f8d5a9a0672d7eb8e7daa5ab3e6202a2b8932493c30374f0451821db161e47cb3af840c0324e27ca2e58272ef
+DIST kvirc-5.2_pre20220629000000.tar.gz 6173590 BLAKE2B b4bfdc307df81a485acb72b33908f82bad0793139543abed03a1b84cae36cba4e11a6b8098cffc9669cb0a7c9072fd6a608589ce03a228b25dfd00b8d7d94b82 SHA512 4369f3703555c8717febfd32c06f6fd8576424cb3a92f9d9e24a5af93acf69ca8707d89a27804457327fd6c30601566d7874c0fc08e12018a3f5440ea988a69e
diff --git a/net-irc/kvirc/kvirc-5.2_pre20210630233331-r1.ebuild b/net-irc/kvirc/kvirc-5.2_pre20210630233331-r1.ebuild
index 6ab9911440be..cf1b5bccf2fc 100644
--- a/net-irc/kvirc/kvirc-5.2_pre20210630233331-r1.ebuild
+++ b/net-irc/kvirc/kvirc-5.2_pre20210630233331-r1.ebuild
@@ -3,7 +3,7 @@
 
 EAPI="8"
 CMAKE_MAKEFILE_GENERATOR="emake"
-PYTHON_COMPAT=( python3_{9..10} )
+PYTHON_COMPAT=( python3_10 )
 
 inherit cmake flag-o-matic python-single-r1 xdg-utils
 
@@ -20,7 +20,7 @@ else
 fi
 
 DESCRIPTION="Advanced IRC Client"
-HOMEPAGE="https://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
 if [[ "${PV}" == "9999" ]]; then
 	SRC_URI=""
 else
diff --git a/net-irc/kvirc/kvirc-5.2_pre20220629000000.ebuild b/net-irc/kvirc/kvirc-5.2_pre20220629000000.ebuild
new file mode 100644
index 000000000000..9246c864d1c0
--- /dev/null
+++ b/net-irc/kvirc/kvirc-5.2_pre20220629000000.ebuild
@@ -0,0 +1,175 @@
+# Copyright 2009-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+CMAKE_MAKEFILE_GENERATOR="emake"
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit cmake flag-o-matic python-single-r1 xdg-utils
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+	KVIRC_GIT_REVISION=""
+	KVIRC_GIT_SOURCES_DATE=""
+else
+	KVIRC_GIT_REVISION="eb3fdd6b1d824f148fd6e582852dcba77fc9a271"
+	KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
+	KVIRC_GIT_SOURCES_DATE="${KVIRC_GIT_SOURCES_DATE:0:4}-${KVIRC_GIT_SOURCES_DATE:4:2}-${KVIRC_GIT_SOURCES_DATE:6:2}"
+fi
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="audiofile +dbus dcc-video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora"
+REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="dev-lang/perl:0
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	kde? ( kde-frameworks/extra-cmake-modules:5 )
+	nls? ( sys-devel/gettext )"
+DEPEND="dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	sys-libs/zlib:0=
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	audiofile? ( media-libs/audiofile )
+	dbus? ( dev-qt/qtdbus:5 )
+	dcc-video? ( dev-qt/qtmultimedia:5[widgets] )
+	kde? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/ki18n:5
+		kde-frameworks/knotifications:5
+		kde-frameworks/kservice:5
+		kde-frameworks/kwindowsystem:5
+		kde-frameworks/kxmlgui:5
+	)
+	perl? ( dev-lang/perl:0= )
+	phonon? ( media-libs/phonon[qt5(+)] )
+	python? ( ${PYTHON_DEPS} )
+	spell? ( app-text/enchant:2 )
+	ssl? ( dev-libs/openssl:0= )
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+		media-libs/libvorbis
+	)"
+RDEPEND="${DEPEND}
+	gsm? ( media-sound/gsm )"
+
+if [[ "${PV}" != "9999" ]]; then
+	S="${WORKDIR}/KVIrc-${KVIRC_GIT_REVISION}"
+fi
+
+DOCS=()
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	if [[ "${PV}" == "9999" ]]; then
+		KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+		KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+	fi
+	einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+	sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX=${libdir#lib}
+		-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+		-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+		-DWANT_ENV_FLAGS=ON
+		-DWANT_VERBOSE=ON
+
+		-DWANT_CRYPT=ON
+		-DWANT_DCC_VOICE=ON
+		-DWANT_IPC=ON
+		-DWANT_IPV6=ON
+		-DWANT_TRANSPARENCY=ON
+
+		-DWANT_AUDIOFILE=$(usex audiofile ON OFF)
+		-DWANT_DCC_VIDEO=$(usex dcc-video ON OFF)
+		-DWANT_DEBUG=$(usex debug ON OFF)
+		-DWANT_DOXYGEN=$(usex doc ON OFF)
+		-DWANT_GETTEXT=$(usex nls ON OFF)
+		-DWANT_GSM=$(usex gsm ON OFF)
+		-DWANT_KDE=$(usex kde ON OFF)
+		-DWANT_MEMORY_PROFILE=$(usex profile ON OFF)
+		-DWANT_OGG_THEORA=$(usex theora ON OFF)
+		-DWANT_OPENSSL=$(usex ssl ON OFF)
+		-DWANT_OSS=$(usex oss ON OFF)
+		-DWANT_PERL=$(usex perl ON OFF)
+		-DWANT_PHONON=$(usex phonon ON OFF)
+		-DWANT_PYTHON=$(usex python ON OFF)
+		-DWANT_QTDBUS=$(usex dbus ON OFF)
+		-DWANT_QTWEBKIT=OFF
+		-DWANT_SPELLCHECKER=$(usex spell ON OFF)
+
+		# COMPILE_SVG_SUPPORT not used in source code.
+		-DWANT_QTSVG=OFF
+	)
+	if use python; then
+		mycmakeargs+=(
+			-DPython3_INCLUDE_DIR="$(python_get_includedir)"
+			-DPython3_LIBRARY="$(python_get_library_path)"
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use doc; then
+		cmake_src_compile devdocs
+	fi
+}
+
+src_install() {
+	cmake_src_install
+
+	if use doc; then
+		(
+			docinto html
+			dodoc -r "${BUILD_DIR}/doc/api/html/"*
+		)
+	fi
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
diff --git a/net-irc/kvirc/kvirc-9999.ebuild b/net-irc/kvirc/kvirc-9999.ebuild
index 4d5f22d2ebd6..8f3d3ec5f184 100644
--- a/net-irc/kvirc/kvirc-9999.ebuild
+++ b/net-irc/kvirc/kvirc-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI="8"
 CMAKE_MAKEFILE_GENERATOR="emake"
-PYTHON_COMPAT=( python3_{9..10} )
+PYTHON_COMPAT=( python3_{10..11} )
 
 inherit cmake flag-o-matic python-single-r1 xdg-utils
 
@@ -20,7 +20,7 @@ else
 fi
 
 DESCRIPTION="Advanced IRC Client"
-HOMEPAGE="https://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
 if [[ "${PV}" == "9999" ]]; then
 	SRC_URI=""
 else
@@ -64,7 +64,7 @@ DEPEND="dev-qt/qtcore:5
 	perl? ( dev-lang/perl:0= )
 	phonon? ( media-libs/phonon[qt5(+)] )
 	python? ( ${PYTHON_DEPS} )
-	spell? ( app-text/enchant:0= )
+	spell? ( app-text/enchant:2 )
 	ssl? ( dev-libs/openssl:0= )
 	theora? (
 		media-libs/libogg
diff --git a/net-irc/kvirc/metadata.xml b/net-irc/kvirc/metadata.xml
index bdde85c80042..38df8ca67e71 100644
--- a/net-irc/kvirc/metadata.xml
+++ b/net-irc/kvirc/metadata.xml
@@ -1,7 +1,14 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-	<!--maintainer-needed-->
+	<maintainer type="person" proxied="yes">
+		<email>alexey+gentoo@asokolov.org</email>
+		<name>Alexey Sokolov</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
 	<use>
 		<flag name="dcc-video">Support video connections over DCC protocol</flag>
 		<flag name="phonon">Support Phonon for audio output</flag>