net-im/gajim: Version Bump, fixes CVE-2015-8688

Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=569936

Package-Manager: portage-2.2.26
Signed-off-by: Justin Lecher <jlec@gentoo.org>

2 files changed, 128 insertions, 0 deletions

diff --git a/net-im/gajim/Manifest b/net-im/gajim/Manifest
index 075fcdc881ef..59a12f72eb33 100644
--- a/net-im/gajim/Manifest
+++ b/net-im/gajim/Manifest
@@ -1 +1,2 @@
 DIST gajim-0.16.4.tar.bz2 4593307 SHA256 2116ad3a5635c54b575ff53eed72fe4651fc50582f5094bfc6113d1cf0d1ce7f SHA512 e8c046aa711207d71080c83d4827400392354eaadb4b431a474fcd94d56bb0fac9f163606a6f7e8abd68c7509158f8e8101b0cc2ecb439443e2966deb707bfdb WHIRLPOOL c6a496f9c02fabbaf76b52e930e5d79f6fad2557e8b458654c538c82041b8ba65bb6f8d75f18438fbabb8aa0e52493494a5847833cc49b70444720b15d6d86a5
+DIST gajim-0.16.5.tar.bz2 4562971 SHA256 a5c015b3b140ec5e47d3842cbe701c9948af5a0cce36314248f0793c2d66d091 SHA512 d69613f9e119f128adc9e81ace2475d3e3e41b47c153ea6ae5a9fcb5be390ec900893e1ab9ce694260898ebced00cd631a3ec4271ac27ed735d3f18dd1e1b6d4 WHIRLPOOL d1405dedd29e867d9a05ca1678f3568acfb53baf7047294af66561a5542f70a02d9b8f22e42abae670e17e6f00461b423e01748ee31b8ada7be7d352af4bb344
diff --git a/net-im/gajim/gajim-0.16.5.ebuild b/net-im/gajim/gajim-0.16.5.ebuild
new file mode 100644
index 000000000000..edf6fd6f7edc
--- /dev/null
+++ b/net-im/gajim/gajim-0.16.5.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite,xml"
+
+AUTOTOOLS_AUTORECONF=true
+
+inherit autotools-utils python-r1 versionator
+
+MY_PV=${PV/_/-}
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Jabber client written in PyGTK"
+HOMEPAGE="http://www.gajim.org/"
+SRC_URI="
+	http://www.gajim.org/downloads/$(get_version_component_range 1-2)/${MY_P}.tar.bz2"
+#	test? ( https://dev.gentoo.org/~jlec/distfiles/${PN}-tests-${PV}.tar.xz )"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="avahi crypt dbus gnome gnome-keyring kde idle jingle libnotify networkmanager nls spell +srv test X xhtml"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	libnotify? ( dbus )
+	avahi? ( dbus )
+	gnome? ( gnome-keyring )"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	dev-python/pygtk:2[${PYTHON_USEDEP}]
+	x11-libs/gtk+:2"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.1
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.17-r1"
+RDEPEND="${COMMON_DEPEND}
+	dev-python/pyasn1[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+	>=dev-python/python-nbxmpp-0.5.3[${PYTHON_USEDEP}]
+	crypt? (
+		app-crypt/gnupg
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+		)
+	dbus? (
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-libs/dbus-glib
+		libnotify? ( dev-python/notify-python[${PYTHON_USEDEP}] )
+		avahi? ( net-dns/avahi[dbus,gtk,python,${PYTHON_USEDEP}] )
+		)
+	gnome? (
+		dev-python/libgnome-python[${PYTHON_USEDEP}]
+		dev-python/egg-python[${PYTHON_USEDEP}]
+		)
+	gnome-keyring? ( dev-python/gnome-keyring-python[${PYTHON_USEDEP}] )
+	idle? ( x11-libs/libXScrnSaver )
+	jingle? ( net-libs/farstream:0.1[python,${PYTHON_USEDEP}] )
+	kde? ( kde-apps/kwalletmanager )
+	networkmanager? (
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+			net-misc/networkmanager
+		)
+	spell? ( app-text/gtkspell:2 )
+	srv? (
+		|| (
+			dev-python/libasyncns-python[${PYTHON_USEDEP}]
+			net-dns/bind-tools
+			)
+		)
+	xhtml? ( dev-python/docutils[${PYTHON_USEDEP}] )"
+
+RESTRICT="test"
+
+S="${WORKDIR}"/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.16-desktop.patch
+	)
+
+src_prepare() {
+	autotools-utils_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	configuration() {
+		local myeconfargs=(
+			$(use_enable nls)
+			$(use_with X x)
+			--docdir="/usr/share/doc/${PF}"
+			--libdir="$(python_get_sitedir)"
+			--enable-site-packages
+		)
+		run_in_build_dir autotools-utils_src_configure
+	}
+	python_foreach_impl configuration
+}
+
+src_compile() {
+	compilation() {
+		run_in_build_dir autotools-utils_src_compile
+	}
+	python_foreach_impl compilation
+}
+
+src_test() {
+	testing() {
+		run_in_build_dir ${PYTHON} test/runtests.py --verbose 3 || die
+	}
+	python_foreach_impl testing
+}
+
+src_install() {
+	installation() {
+		run_in_build_dir autotools-utils_src_install
+		python_optimize
+	}
+	python_foreach_impl installation
+
+	rm "${ED}/usr/share/doc/${PF}/README.html" || die
+	dohtml README.html
+}