net-analyzer/net-snmp: add 5.9.4

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 241 insertions, 1 deletions

diff --git a/net-analyzer/net-snmp/Manifest b/net-analyzer/net-snmp/Manifest
index e203e4bdb4fb..b0d07d45b397 100644
--- a/net-analyzer/net-snmp/Manifest
+++ b/net-analyzer/net-snmp/Manifest
@@ -1,2 +1,3 @@
 DIST net-snmp-5.7.3-patches-3.tar.xz 3176 BLAKE2B 1a71d6743afb841f664c6058e32c7c411af62b0f36acd3bb9251804893ed12f462a0c5bab828e309eeec7824def2dca8fa866350b90a62ec4f0df1141b51ecae SHA512 d8a91b9668320a1e19d062eb86dd4d16beb7c2d15ac7ebbb9d2a4bd298af39bbb0a2613504dbb0057cccdec731f08f2308c5a15395e1fbc29bb0611ed8aca636
 DIST net-snmp-5.9.3.tar.gz 6646950 BLAKE2B b8e3de60e178ec16ad2848ad77f3bd4cbd35eaa9be103c0fa5d17514c29df4e69015ac53b54c9e565e3032b0c0bb47c19729e65310a6acefae901e101ea49451 SHA512 a476df4967029a2eb03d27b0e250170785d0a8c143d49b900ee958c3cbdfaccd415b70af40f6fbed9cb8819d522c35a6073a431091d908ccc7c018fa0aaa2abc
+DIST net-snmp-5.9.4.tar.gz 6681606 BLAKE2B 2f3dfdc4ce2f4d9a1a771a77e0b0c427a89e3de6dc217009df385baabc7d860ca7714fa76360a4d14521f1b88c9c13ad46b25d3975e33e8bc4bce3eb3b27b99d SHA512 a510fa91a21e9ddc86a12fd1d0bc6b356e63f3ea53f184d2e31439004d41d902390664134dc40b3b828eabb4282eaf3da628a07c4d480fa00eff7e700950c423
diff --git a/net-analyzer/net-snmp/net-snmp-5.9.4.ebuild b/net-analyzer/net-snmp/net-snmp-5.9.4.ebuild
new file mode 100644
index 000000000000..b3f01b402c12
--- /dev/null
+++ b/net-analyzer/net-snmp/net-snmp-5.9.4.ebuild
@@ -0,0 +1,239 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_OPTIONAL=yes
+DISTUTILS_SINGLE_IMPL=yes
+GENTOO_DEPEND_ON_PERL=no
+PYTHON_COMPAT=( python3_{9..11} )
+WANT_AUTOMAKE=none
+
+inherit autotools distutils-r1 perl-module systemd
+
+DESCRIPTION="Software for generating and retrieving SNMP data"
+HOMEPAGE="https://www.net-snmp.org/"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/net-snmp/net-snmp"
+	inherit git-r3
+else
+	# https://github.com/net-snmp/net-snmp/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+	SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${P}.tar.gz"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+SRC_URI+=" https://dev.gentoo.org/~jsmolic/distfiles/${PN}-5.7.3-patches-3.tar.xz"
+
+# GPL-2 for the init scripts
+LICENSE="HPND BSD GPL-2"
+SLOT="0/40"
+IUSE="
+	X bzip2 doc elf kmem ipv6 lm-sensors mfd-rewrites minimal mysql
+	netlink pcap pci pcre perl python rpm selinux smux ssl tcpd ucd-compat valgrind zlib
+"
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+	rpm? ( bzip2 zlib )
+"
+RESTRICT="test"
+
+COMMON_DEPEND="
+	virtual/libcrypt:=
+	bzip2? ( app-arch/bzip2 )
+	elf? ( dev-libs/elfutils )
+	lm-sensors? ( sys-apps/lm-sensors )
+	mysql? ( dev-db/mysql-connector-c:0= )
+	netlink? ( dev-libs/libnl:3 )
+	pcap? ( net-libs/libpcap )
+	pci? ( sys-apps/pciutils )
+	pcre? ( dev-libs/libpcre )
+	perl? ( dev-lang/perl:= )
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/setuptools[${PYTHON_USEDEP}]
+		')
+		${PYTHON_DEPS}
+	)
+	rpm? (
+		app-arch/rpm
+		dev-libs/popt
+	)
+	ssl? (
+		>=dev-libs/openssl-0.9.6d:0=
+	)
+	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
+	zlib? ( >=sys-libs/zlib-1.1.4 )
+"
+BDEPEND="doc? ( app-doc/doxygen )"
+DEPEND="
+	${COMMON_DEPEND}
+	valgrind? ( dev-util/valgrind )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	perl? (
+		X? ( dev-perl/Tk )
+		!minimal? (
+			virtual/perl-Carp
+			virtual/perl-Data-Dumper
+			virtual/perl-Getopt-Long
+			dev-perl/JSON
+			dev-perl/Mail-Sender
+			dev-perl/TermReadKey
+			virtual/perl-Term-ReadLine
+		)
+	)
+	selinux? ( sec-policy/selinux-snmp )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.8-pcap.patch
+	"${FILESDIR}"/${PN}-5.8.1-mysqlclient.patch
+	"${FILESDIR}"/${PN}-5.9-MakeMaker.patch
+	# https://github.com/net-snmp/net-snmp/pull/493
+	"${FILESDIR}"/${PN}-5.9.3-0001-Fix-LDFLAGS-vs-LIBS-ordering.patch
+	"${FILESDIR}"/${PN}-5.9.3-0002-Tidy-up-net-snmp-config-output.patch
+	"${FILESDIR}"/${PN}-5.9.3-0003-Prune-Libs.private-entries-in-netsnmp-.pc.in.patch
+	"${FILESDIR}"/${PN}-5.9.3-0004-Search-for-ltinfo-in-configure-if-needed.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	default
+
+	[[ ${PV} == 9999 ]] && git-r3_src_unpack
+}
+
+src_prepare() {
+	# snmpconf generates config files with proper selinux context
+	use selinux && eapply "${FILESDIR}"/${PN}-5.1.2-snmpconf-selinux.patch
+
+	mv "${WORKDIR}"/patches/0001-Fix-toolchain-quadruplet-detection-Gentoo-bug-432004.patch{,.disabled} || die
+	mv "${WORKDIR}"/patches/0002-Respect-DESTDIR-for-pythoninstall.patch{,.disabled} || die
+	mv "${WORKDIR}"/patches/0004-Don-t-report-CFLAGS-and-LDFLAGS-in-net-snmp-config.patch{,.disabled} || die
+	mv "${WORKDIR}"/patches/0005-Respect-LDFLAGS-properly.patch{,.disabled} || die
+	eapply "${WORKDIR}"/patches/*.patch
+
+	default
+
+	eautoconf
+}
+
+src_configure() {
+	# keep this in the same line, configure.ac arguments are passed down to config.h
+	local mibs="host ucd-snmp/dlmod ucd-snmp/diskio ucd-snmp/extensible mibII/mta_sendmail etherlike-mib/dot3StatsTable"
+	use lm-sensors && mibs="${mibs} ucd-snmp/lmsensorsMib"
+	use smux && mibs="${mibs} smux"
+
+	# Assume /etc/mtab is not present with a recent baselayout/openrc (bug #565136)
+	use kernel_linux && export ac_cv_ETC_MNTTAB=/etc/mtab
+
+	export ac_cv_header_valgrind_{valgrind,memcheck}_h=$(usex valgrind)
+
+	econf \
+		$(use_enable !ssl internal-md5) \
+		$(use_enable ipv6) \
+		$(use_enable mfd-rewrites) \
+		$(use_enable perl embedded-perl) \
+		$(use_enable ucd-compat ucd-snmp-compatibility) \
+		$(use_with bzip2) \
+		$(use_with elf) \
+		$(use_with kmem kmem-usage) \
+		$(use_with mysql) \
+		$(use_with netlink nl) \
+		$(use_with pcap) \
+		$(use_with pci) \
+		$(use_with pcre) \
+		$(use_with perl perl-modules INSTALLDIRS=vendor) \
+		$(use_with python python-modules) \
+		$(use_with rpm) \
+		$(use_with ssl openssl) \
+		$(use_with tcpd libwrap) \
+		$(use_with zlib) \
+		--enable-shared \
+		--with-default-snmp-version="3" \
+		--with-ldflags="${LDFLAGS}" \
+		--with-logfile="/var/log/net-snmpd.log" \
+		--with-mib-modules="${mibs}" \
+		--with-persistent-directory="/var/lib/net-snmp" \
+		--with-sys-contact="root@unknown" \
+		--with-sys-location="Unknown"
+}
+
+src_compile() {
+	emake sedscript
+
+	local subdir
+	for subdir in snmplib agent/mibgroup agent apps .; do
+		emake OTHERLDFLAGS="${LDFLAGS}" -C ${subdir} all
+	done
+
+	use doc && emake docsdox
+}
+
+src_install() {
+	# bug #317965
+	emake -j1 DESTDIR="${D}" install
+
+	use python && python_optimize
+
+	if use perl ; then
+		perl_delete_localpod
+		if ! use X; then
+			rm "${D}"/usr/bin/tkmib || die
+		fi
+	else
+		rm -f \
+			"${D}"/usr/bin/fixproc \
+			"${D}"/usr/bin/ipf-mod.pl \
+			"${D}"/usr/bin/mib2c \
+			"${D}"/usr/bin/net-snmp-cert \
+			"${D}"/usr/bin/snmp-bridge-mib \
+			"${D}"/usr/bin/snmpcheck \
+			"${D}"/usr/bin/snmpconf \
+			"${D}"/usr/bin/tkmib \
+			"${D}"/usr/bin/traptoemail \
+			"${D}"/usr/share/snmp/mib2c.perl.conf \
+			"${D}"/usr/share/snmp/snmp_perl_trapd.pl \
+			|| die
+	fi
+
+	dodoc AGENT.txt ChangeLog FAQ INSTALL NEWS PORTING README* TODO
+	newdoc EXAMPLE.conf.def EXAMPLE.conf
+
+	if use doc; then
+		docinto html
+		dodoc -r docs/html/*
+	fi
+
+	keepdir /var/lib/net-snmp
+
+	newinitd "${FILESDIR}"/snmpd.init.2 snmpd
+	newconfd "${FILESDIR}"/snmpd.conf snmpd
+
+	newinitd "${FILESDIR}"/snmptrapd.init.2 snmptrapd
+	newconfd "${FILESDIR}"/snmptrapd.conf snmptrapd
+
+	systemd_dounit "${FILESDIR}"/snmpd.service
+	systemd_dounit "${FILESDIR}"/snmptrapd.service
+
+	insinto /etc/snmp
+	newins "${S}"/EXAMPLE.conf snmpd.conf.example
+
+	# Remove everything not required for an agent.
+	# Keep only the snmpd, snmptrapd, MIBs, headers and libraries.
+	if use minimal; then
+		rm -rf \
+			"${D}"/**/*.pl \
+			"${D}"/usr/bin/{encode_keychange,snmp{get,getnext,set,usm,walk,bulkwalk,table,trap,bulkget,translate,status,delta,test,df,vacm,netstat,inform,check,conf},fixproc,traptoemail} \
+			"${D}"/usr/share/snmp/*.conf \
+			"${D}"/usr/share/snmp/snmpconf-data \
+			|| die
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/net-analyzer/net-snmp/net-snmp-9999.ebuild b/net-analyzer/net-snmp/net-snmp-9999.ebuild
index 1c946612076d..e00752e65c72 100644
--- a/net-analyzer/net-snmp/net-snmp-9999.ebuild
+++ b/net-analyzer/net-snmp/net-snmp-9999.ebuild
@@ -18,7 +18,7 @@ if [[ ${PV} == 9999 ]] ; then
 	inherit git-r3
 else
 	# https://github.com/net-snmp/net-snmp/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
-	SRC_URI="mirror://sourceforge/${PN}/${PV}/${P}.tar.gz"
+	SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${P}.tar.gz"
 
 	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 fi