media-sound/pithos: add 1.6.1

Closes: https://bugs.gentoo.org/906300
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/media-sound/pithos/Manifest b/media-sound/pithos/Manifest
index 7383aaa8d8b7..6ec15847f84e 100644
--- a/media-sound/pithos/Manifest
+++ b/media-sound/pithos/Manifest
@@ -1 +1,2 @@
 DIST pithos-1.6.0.tar.gz 122025 BLAKE2B c621fe58998790f0eb0159d29c40ac4abf2feff2be790c12008be86387bf628b170e3256c2f3ac83e9b2be254d96d4aa7e3e56ac780b0d59a446d0e158d96d15 SHA512 9e7b1d1456a769882a58639bf93194ec0228d21b7b7d1404224346016532620bb862e7d79a2c741d8ef44238c22741e4fd67bc22eadc8d207818a0ece33411ab
+DIST pithos-1.6.1.tar.xz 99552 BLAKE2B 048071e4c1df0cf517de64fa19cbe589972c8a34eea2f068c7d183726523c633ce36cc87344e13a8bb31d6aa4a08365b1e9691e822e5d9a7224c318dbfd7df1e SHA512 e1a13d2c789e40bf135ed551d06dfe44bf948bfe84a8bbb3f4afcab70bbcdc4f1d3f82d25f5e8d930888dd6fa04795fa2d9d47515d4199647be854c9c4a84591
diff --git a/media-sound/pithos/pithos-1.6.1.ebuild b/media-sound/pithos/pithos-1.6.1.ebuild
new file mode 100644
index 000000000000..5a854cf42454
--- /dev/null
+++ b/media-sound/pithos/pithos-1.6.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+inherit xdg meson gnome2-utils virtualx python-r1
+
+DESCRIPTION="Pandora.com client for the GNOME desktop"
+HOMEPAGE="https://pithos.github.io/"
+SRC_URI="https://github.com/pithos/pithos/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="appindicator +keybinder libnotify test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-python/pygobject[${PYTHON_USEDEP}]
+	app-crypt/libsecret[introspection]
+	dev-libs/appstream-glib[introspection]
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/pylast[${PYTHON_USEDEP}]
+	media-libs/gstreamer:1.0[introspection]
+	media-plugins/gst-plugins-meta:1.0[aac,http,mp3]
+	x11-libs/gtk+:3[introspection]
+	x11-libs/pango[introspection]
+	x11-themes/gnome-icon-theme-symbolic
+	appindicator? ( dev-libs/libdbusmenu[gtk3,introspection] )
+	keybinder? ( dev-libs/keybinder:3[introspection] )
+	libnotify? ( x11-libs/libnotify[introspection] )
+"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		${RDEPEND}
+		dev-libs/glib:2
+		dev-util/desktop-file-utils
+	)
+"
+
+src_configure() {
+	python_foreach_impl meson_src_configure
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_test() {
+	virtx python_foreach_impl meson_src_test
+}
+
+src_install() {
+	python_foreach_impl meson_src_install
+	einstalldocs
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}