kde-plasma/plasma-welcome: 5.27.9 version bump

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 61 insertions, 0 deletions

diff --git a/kde-plasma/plasma-welcome/Manifest b/kde-plasma/plasma-welcome/Manifest
index 354d1f481844..091287b52359 100644
--- a/kde-plasma/plasma-welcome/Manifest
+++ b/kde-plasma/plasma-welcome/Manifest
@@ -1 +1,2 @@
 DIST plasma-welcome-5.27.8.tar.xz 835848 BLAKE2B 46b2f29ae76dc0e3f45bdb694078c91c960b60a1648da48cffd228675f817fb60311449723c10d9271f24dd994449df4cab85db8821464f7f34608a7b3d960ec SHA512 925e8621c2df0320e4364d8c9a73f85897ff164bedc3e1bf89e61be62da3df60516254d06a3e5cb44dca59c6a52f3e4bf5e9feeb2010261d72d98534b0efee60
+DIST plasma-welcome-5.27.9.tar.xz 835908 BLAKE2B fc7ce9d9a4d141c62f98676e072bb6dc8915e0b880602effd16c2123ef7bfd0787b2eee81fdd43cf32ec9efefe075730134e833dcfe74b4aa350c4c42c83f0e1 SHA512 c3a4e2f65ff471f56ee1efc111b1183bb1f00f6df488d7a6803fe478985769757ec26c43ef1f4617020f1d8c9d172fd10a904cdf07f619f7e6537044b4d3cd01
diff --git a/kde-plasma/plasma-welcome/plasma-welcome-5.27.9.ebuild b/kde-plasma/plasma-welcome/plasma-welcome-5.27.9.ebuild
new file mode 100644
index 000000000000..e61d70604e59
--- /dev/null
+++ b/kde-plasma/plasma-welcome/plasma-welcome-5.27.9.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm plasma.kde.org
+
+DESCRIPTION="A friendly onboarding wizard for Plasma"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="discover +kaccounts telemetry"
+
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	kaccounts? ( kde-apps/kaccounts-integration:5 )
+	telemetry? ( dev-libs/kuserfeedback:5 )
+"
+RDEPEND="${DEPEND}
+	discover? ( kde-plasma/discover:5 )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.27.4.1-kaccounts-optional.patch" )
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use discover; then
+		sed -e "s:pageStack.push(discover);:// & disabled by IUSE=discover:" \
+			-i src/contents/ui/main.qml || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kaccounts KAccounts)
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+	ecm_src_configure
+}