kde-frameworks/breeze-icons: 5.108.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 57 insertions, 0 deletions

diff --git a/kde-frameworks/breeze-icons/Manifest b/kde-frameworks/breeze-icons/Manifest
index 448349a49112..dc8b2edd0235 100644
--- a/kde-frameworks/breeze-icons/Manifest
+++ b/kde-frameworks/breeze-icons/Manifest
@@ -1,2 +1,3 @@
 DIST breeze-icons-5.106.0.tar.xz 2172332 BLAKE2B 164f967fed37ce03081ebac796a054230007d68fd0ee4c9816098f394b4b9f582a2b8c0b9add1c476929556decc3965ef560daf49bc48662379c7001bd2efc46 SHA512 ff4a7e40872f6dadee5d4d8190813b5246cb79f3ca3a0af156db258fb2e3ef94042a26e93ccaaa53c9372c512317629316eff10e0292ba0127ed9f354ab47c79
 DIST breeze-icons-5.107.0.tar.xz 2172508 BLAKE2B 8a813e76f84d34a96715597d85cbb35b1f52a54909b55b6fc4610955b3ef795f23e49531311367ff164206e35e243233da6c8885f7234b546450aaa785b2e168 SHA512 0f2ecb30c9aa47187c5eb4c7c35ee6fd53f1dac79683072edaf10f12f8e635c8d42f2d29d4ba2299d7d8c46c10f416c93d2b9f2e6dfc2e54e053b178c3610cb9
+DIST breeze-icons-5.108.0.tar.xz 2172924 BLAKE2B 3a1d265e8e11df3048d18a806e145a46ef0f0a19ebc3d19e99f97da4d90211782715c9e9106814c8758dbbecbf8a448bcbc56d78c9636a58e201e11ac8820ecf SHA512 d540c938f4aae2d25074ce97ba9d3ec82514068192897bfa2c3387977778cac9e0753e182af6da4fefff5ff79bc68a71af6eaedbf37eba9c6392ccd0ba59612d
diff --git a/kde-frameworks/breeze-icons/breeze-icons-5.108.0.ebuild b/kde-frameworks/breeze-icons/breeze-icons-5.108.0.ebuild
new file mode 100644
index 000000000000..14f4bfe07248
--- /dev/null
+++ b/kde-frameworks/breeze-icons/breeze-icons-5.108.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-2)
+PYTHON_COMPAT=( python3_{10..11} )
+inherit cmake frameworks.kde.org python-any-r1 xdg-utils
+
+DESCRIPTION="Breeze SVG icon theme"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-qt/qttest:5 )"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtcore:5
+	>=kde-frameworks/extra-cmake-modules-${PVCUT}:5
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	python_has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use test || cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# bug 770988
+	find "${ED}"/usr/share/icons/ -type d -empty -delete || die
+	find "${ED}"/usr/share/icons/ -xtype l -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}