kde-apps/kget: 21.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 81 insertions, 0 deletions

diff --git a/kde-apps/kget/Manifest b/kde-apps/kget/Manifest
index 51ddeb9fe3ab..d577e3ee99ec 100644
--- a/kde-apps/kget/Manifest
+++ b/kde-apps/kget/Manifest
@@ -1 +1,2 @@
 DIST kget-21.04.3.tar.xz 5636204 BLAKE2B d0f5576ab4dd755825f4482de1ce3362197f24181e1e8c922acf039c6b72eb65f205658e34320645cc8a2f40e8e4f19cad09202bbdb478ffeb38ebbacc1c2a28 SHA512 58d2a18d7f918ac161cd19438a4aeeec86e0df85245903cc00fac1cdebe2dca6bf471d12f54301ff9b60899471726c3e410b870ef3aa251f3994e3ee1fb6d30d
+DIST kget-21.08.0.tar.xz 5634888 BLAKE2B cde3f8db4ff587b7789634145de90b0f122896efaf46a0896f77c74595c6138edbb497e43f9299e3cf92db98c817e3e276dffc1b726a50663187c2dad955bda0 SHA512 e71dc3fa31da5b224cec08855c2ffda74ef5203e8a3d53ea36f041845d299fc006d937e4d86f450aa85502f483de6dc203b6a07476e388fdead0c9552e470057
diff --git a/kde-apps/kget/kget-21.08.0.ebuild b/kde-apps/kget/kget-21.08.0.ebuild
new file mode 100644
index 000000000000..a89428e17f41
--- /dev/null
+++ b/kde-apps/kget/kget-21.08.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=5.84.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Advanced download manager by KDE"
+HOMEPAGE="https://apps.kde.org/kget/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="bittorrent gpg kde mms sqlite"
+
+RDEPEND="
+	>=app-crypt/qca-2.3.0:2
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	bittorrent? ( >=net-libs/libktorrent-21.07.80:5 )
+	gpg? ( app-crypt/gpgme[qt5] )
+	kde? ( kde-plasma/libkworkspace:5 )
+	mms? ( media-libs/libmms )
+	sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package bittorrent KF5Torrent)
+		$(cmake_use_find_package gpg Gpgmepp)
+		$(cmake_use_find_package kde LibKWorkspace)
+		$(cmake_use_find_package mms LibMms)
+		$(cmake_use_find_package sqlite Sqlite)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bug 756817: schedulertest fails, see also upstream commit 45735cfa
+	# filedeletertest hangs.
+	local myctestargs=(
+		-E "(schedulertest|filedeletertest)"
+	)
+
+	ecm_src_test
+}