kde-apps/kaddressbook: 22.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/kde-apps/kaddressbook/Manifest b/kde-apps/kaddressbook/Manifest
index 928c9100a2bc..84925170c318 100644
--- a/kde-apps/kaddressbook/Manifest
+++ b/kde-apps/kaddressbook/Manifest
@@ -1 +1,2 @@
 DIST kaddressbook-22.08.3.tar.xz 3336612 BLAKE2B 9e960cd55bb969a942a79cbce8a1092bd5083e9f054d8f63b40197992d9438a2461200adb4d9d517413b3e369689cf48795484dcc87df1aa7bebeda9a7669e7a SHA512 b4fbc9c4f5dc87b8ceb0175523dbd0d1d21c589005f6dc2e137c8d4bd1096a289955ab7533b595a4ab99587ed0c9f259096e991ec8a2015ab4023de9c383364a
+DIST kaddressbook-22.12.0.tar.xz 3457104 BLAKE2B 553d99edf7f8e75122fc3437df5f0ae0360639fad33c6dcc24d0603e92e0f121d5f489432847f279f410d4520e82bdf6b1b73305507e3c07fb52efb8a1ab325f SHA512 a433c0e1aa5c9b8dd18bfbb010a9fc94ebd458b6a7848c14797d1fe30d44ca31553eef537e51bc6955cecb1d2aaee01850166dbe329ad749101e4e4837c97f91
diff --git a/kde-apps/kaddressbook/kaddressbook-22.12.0.ebuild b/kde-apps/kaddressbook/kaddressbook-22.12.0.ebuild
new file mode 100644
index 000000000000..72c59fa5c5be
--- /dev/null
+++ b/kde-apps/kaddressbook/kaddressbook-22.12.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.99.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org optfeature
+
+DESCRIPTION="Address book application based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/kaddressbook/"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="telemetry"
+
+DEPEND="
+	dev-libs/grantlee:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/akonadi-${PVCUT}:5
+	>=kde-apps/akonadi-contacts-${PVCUT}:5
+	>=kde-apps/akonadi-search-${PVCUT}:5
+	>=kde-apps/grantleetheme-${PVCUT}:5
+	>=kde-apps/kontactinterface-${PVCUT}:5
+	>=kde-apps/libgravatar-${PVCUT}:5
+	>=kde-apps/libkdepim-${PVCUT}:5
+	>=kde-apps/pimcommon-${PVCUT}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcontacts-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/prison-${KFMIN}:5
+	telemetry? ( >=dev-libs/kuserfeedback-1.2.0:5 )
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/kdepim-runtime-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Postal addresses" kde-apps/kdepim-addons:${SLOT}
+	fi
+	ecm_pkg_postinst
+}