kde-apps/gwenview: 21.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 104 insertions, 0 deletions

diff --git a/kde-apps/gwenview/Manifest b/kde-apps/gwenview/Manifest
index 2c77f4f33c1f..72ac5f7df354 100644
--- a/kde-apps/gwenview/Manifest
+++ b/kde-apps/gwenview/Manifest
@@ -1 +1,2 @@
 DIST gwenview-21.04.3.tar.xz 6772236 BLAKE2B 83310fd6f290b4980dac774fe46ac8455b0cfde1987ffd76a43f313e8a185381b1eb10186fcecb1a198fa0872266f28aa3d1803a8ee92c0910b488392db12c6e SHA512 83caa2da3afe552a5c48955136a54e5c53b2ffd83ee68fd5f7caee849d9d7547a566941c41f7b13973e8f292a31ad9ad9d9ccdea7f44b76cab8b2f97efe160d1
+DIST gwenview-21.08.0.tar.xz 6818232 BLAKE2B d7dcad81b923e5e17c3c59b84bb1e4915831edb1f7d85157cee1cf3a3ba4d611ed552ab9cb8915cb0d821f861beb6f86673da85e78ac4108b8ab5349f7471d1e SHA512 0854627ab451df6e14348b15fa58bfdd0fd09f03d16ed698e913f25ffe560671aec9623af5a3f5f7597f0c9084e4d1cb67567c9455f95b5841cc82d150400fc2
diff --git a/kde-apps/gwenview/gwenview-21.08.0.ebuild b/kde-apps/gwenview/gwenview-21.08.0.ebuild
new file mode 100644
index 000000000000..9517c12e0fe1
--- /dev/null
+++ b/kde-apps/gwenview/gwenview-21.08.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.84.0
+QTMIN=5.15.2
+inherit ecm kde.org optfeature
+
+DESCRIPTION="Image viewer by KDE"
+HOMEPAGE="https://apps.kde.org/gwenview/ https://userbase.kde.org/Gwenview"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="activities fits kipi +mpris raw semantic-desktop share X"
+
+# requires running environment
+RESTRICT+=" test"
+
+COMMON_DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	media-gfx/exiv2:=
+	media-libs/lcms:2
+	media-libs/libpng:0=
+	>=media-libs/phonon-4.11.0
+	media-libs/tiff
+	virtual/jpeg:0
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+	fits? ( sci-libs/cfitsio )
+	kipi? ( >=kde-apps/libkipi-${PVCUT}:5= )
+	mpris? ( >=dev-qt/qtdbus-${QTMIN}:5 )
+	raw? ( >=kde-apps/libkdcraw-${PVCUT}:5 )
+	semantic-desktop? (
+		>=kde-frameworks/baloo-${KFMIN}:5
+		>=kde-frameworks/kfilemetadata-${KFMIN}:5
+	)
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtimageformats-${QTMIN}:5
+	>=kde-frameworks/kimageformats-${KFMIN}:5
+	kipi? ( >=kde-apps/kipi-plugins-${PVCUT}:5 )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use mpris; then
+		# FIXME: upstream a better solution
+		sed -e "/set(HAVE_QTDBUS/s/\${Qt5DBus_FOUND}/0/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package fits CFitsio)
+		$(cmake_use_find_package kipi KF5Kipi)
+		$(cmake_use_find_package raw KF5KDcraw)
+		-DGWENVIEW_SEMANTICINFO_BACKEND=$(usex semantic-desktop Baloo None)
+		$(cmake_use_find_package share KF5Purpose)
+		$(cmake_use_find_package X X11)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "SVG support" kde-apps/svgpart:${SLOT}
+	fi
+	ecm_pkg_postinst
+}