dev-util/lldb: Bump to 4.0.0rc1

2 files changed, 119 insertions, 1 deletions

diff --git a/dev-util/lldb/lldb-4.0.0_rc1.ebuild b/dev-util/lldb/lldb-4.0.0_rc1.ebuild
new file mode 100644
index 000000000000..700832c0a573
--- /dev/null
+++ b/dev-util/lldb/lldb-4.0.0_rc1.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+# (needed due to CMAKE_BUILD_TYPE != Gentoo)
+CMAKE_MIN_VERSION=3.7.0-r1
+PYTHON_COMPAT=( python2_7 )
+
+inherit cmake-utils git-r3 python-single-r1 toolchain-funcs
+
+DESCRIPTION="The LLVM debugger"
+HOMEPAGE="http://llvm.org/"
+SRC_URI=""
+EGIT_REPO_URI="http://llvm.org/git/lldb.git
+	https://github.com/llvm-mirror/lldb.git"
+EGIT_BRANCH="release_40"
+EGIT_COMMIT="fcd2aac9f179b968a20cf0231c3386dcef8a6659"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="libedit ncurses python test"
+
+RDEPEND="
+	libedit? ( dev-libs/libedit:0= )
+	ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
+	python? ( dev-python/six[${PYTHON_USEDEP}]
+		${PYTHON_DEPS} )
+	~sys-devel/clang-${PV}[xml]
+	~sys-devel/llvm-${PV}
+	!<sys-devel/llvm-4.0"
+# swig-3.0.9+ generates invalid wrappers, #598708
+# upstream: https://github.com/swig/swig/issues/769
+DEPEND="${RDEPEND}
+	python? ( <dev-lang/swig-3.0.9 )
+	test? ( ~dev-python/lit-${PV}[${PYTHON_USEDEP}] )
+	${PYTHON_DEPS}"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+# least intrusive of all
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+src_unpack() {
+	if use test; then
+		# needed for patched gtest
+		git-r3_fetch "http://llvm.org/git/llvm.git
+			https://github.com/llvm-mirror/llvm.git" \
+			c329efbc3c94928fb826ed146897aada0459c983
+	fi
+	git-r3_fetch
+
+	if use test; then
+		git-r3_checkout http://llvm.org/git/llvm.git \
+			"${WORKDIR}"/llvm
+	fi
+	git-r3_checkout
+}
+
+src_configure() {
+	local libdir=$(get_libdir)
+	local mycmakeargs=(
+		-DLLDB_DISABLE_CURSES=$(usex !ncurses)
+		-DLLDB_DISABLE_LIBEDIT=$(usex !libedit)
+		-DLLDB_DISABLE_PYTHON=$(usex !python)
+		-DLLVM_ENABLE_TERMINFO=$(usex ncurses)
+
+		-DLLVM_BUILD_TESTS=$(usex test)
+		# compilers for lit tests
+		-DLLDB_TEST_C_COMPILER="${EPREFIX}/usr/bin/clang"
+		-DLLDB_TEST_CXX_COMPILER="${EPREFIX}/usr/bin/clang++"
+		# compiler for ole' python tests
+		-DLLDB_TEST_COMPILER="${EPREFIX}/usr/bin/clang"
+
+		# TODO: fix upstream to detect this properly
+		-DHAVE_LIBDL=ON
+		-DHAVE_LIBPTHREAD=ON
+
+		# normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
+		# and TERMINFO_LIBS... so just force FindCurses.cmake to use
+		# ncurses with complete library set (including autodetection
+		# of -ltinfo)
+		-DCURSES_NEED_NCURSES=ON
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+		-DLIT_COMMAND="${EPREFIX}/usr/bin/lit"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	cmake-utils_src_make check-lldb-lit
+	use python && cmake-utils_src_make check-lldb
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# oh my...
+	if use python; then
+		# remove bundled six module
+		rm "${D}$(python_get_sitedir)/six.py" || die
+
+		# remove custom readline.so for now
+		# TODO: figure out how to deal with it
+		# upstream is basically building a custom readline.so with -ledit
+		# to avoid symbol collisions between readline and libedit...
+		rm "${D}$(python_get_sitedir)/readline.so" || die
+
+		# byte-compile the modules
+		python_optimize
+	fi
+}
diff --git a/dev-util/lldb/lldb-9999.ebuild b/dev-util/lldb/lldb-9999.ebuild
index 32e093bcbb33..6d1a954e59fd 100644
--- a/dev-util/lldb/lldb-9999.ebuild
+++ b/dev-util/lldb/lldb-9999.ebuild
@@ -34,7 +34,7 @@ RDEPEND="
 # upstream: https://github.com/swig/swig/issues/769
 DEPEND="${RDEPEND}
 	python? ( <dev-lang/swig-3.0.9 )
-	test? ( dev-python/lit[${PYTHON_USEDEP}] )
+	test? ( ~dev-python/lit-${PV}[${PYTHON_USEDEP}] )
 	${PYTHON_DEPS}"
 
 REQUIRED_USE=${PYTHON_REQUIRED_USE}