dev-python/sphinxcontrib-qthelp: enable py3.12

and fix the failing test.

Closes: https://bugs.gentoo.org/858821
Signed-off-by: Petr Vaněk <arkamar@atlas.cz>
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-python/sphinxcontrib-qthelp/sphinxcontrib-qthelp-1.0.3-r2.ebuild b/dev-python/sphinxcontrib-qthelp/sphinxcontrib-qthelp-1.0.3-r2.ebuild
new file mode 100644
index 000000000000..ae6e7514abb1
--- /dev/null
+++ b/dev-python/sphinxcontrib-qthelp/sphinxcontrib-qthelp-1.0.3-r2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Sphinx extension which outputs QtHelp documents"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinxcontrib-qthelp/
+	https://pypi.org/project/sphinxcontrib-qthelp/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+
+PDEPEND="
+	>=dev-python/sphinx-2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? ( ${PDEPEND} )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# This is already fixed in upstream, remove it on next version bump,
+	# see https://github.com/sphinx-doc/sphinxcontrib-qthelp/pull/14
+	sed -i 's/.text()/.read_text()/' tests/test_qthelp.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	distutils_write_namespace sphinxcontrib
+	cd "${T}" || die
+	epytest "${S}"/tests
+}