dev-python/oslo-i18n: bup

Package-Manager: portage-2.2.26

1 files changed, 63 insertions, 0 deletions

diff --git a/dev-python/oslo-i18n/oslo-i18n-3.5.0.ebuild b/dev-python/oslo-i18n/oslo-i18n-3.5.0.ebuild
new file mode 100644
index 000000000000..e1125b335b1f
--- /dev/null
+++ b/dev-python/oslo-i18n/oslo-i18n-3.5.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_{3,4,5}} )
+
+inherit distutils-r1 vcs-snapshot
+
+MY_PN=${PN/-/.}
+
+DESCRIPTION="Oslo i18n library"
+HOMEPAGE="http://launchpad.net/oslo"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND=">dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]"
+CRDEPEND=">=dev-python/pbr-1.8[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CRDEPEND}
+	test? (
+		${CDEPEND}
+		>=dev-python/mock-1.2[${PYTHON_USEDEP}]
+		>=dev-python/coverage-3.6[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-3.7.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		${CDEPEND}
+		>=dev-python/oslo-sphinx-2.5.0[${PYTHON_USEDEP}]
+		!~dev-python/oslo-sphinx-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.2.0[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CRDEPEND}
+	>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPYTHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}