dev-python/multidict: version bump to 4.5.2

Signed-off-by: Tim Harder <radhermit@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/multidict/multidict-4.5.2.ebuild b/dev-python/multidict/multidict-4.5.2.ebuild
new file mode 100644
index 000000000000..a2f8fb69a3f1
--- /dev/null
+++ b/dev-python/multidict/multidict-4.5.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="multidict implementation"
+HOMEPAGE="https://github.com/aio-libs/multidict/"
+SRC_URI="https://github.com/aio-libs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+RDEPEND=""
+
+python_prepare_all() {
+	# don't use pytest-runner for tests
+	sed -i "s|'pytest-runner'||" setup.py || die
+
+	# don't enable coverage or other pytest settings
+	rm pytest.ini || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test -v tests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}