dev-python/django: Bump to 4.1.7

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 56fbcdcb4380..966f68f30c83 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -4,3 +4,5 @@ DIST Django-4.0.9.checksum.txt 2547 BLAKE2B 9e855836f392a88e8502408e60e4ea44609a
 DIST Django-4.0.9.tar.gz 10410176 BLAKE2B 41df0c4f01b9802751e84366e9c2efbf6699a4989229c3b787a6c33fd9dd51d8dd7c1487f47e9a9fc94fa513c8ae8a849ec0bee78061c2ae9c1b218b0d7336df SHA512 f6ac387e270cbbf1217af6667afd7d2a0b1ccb7738904ea35aaf9d71d0f40d7ea170283a8ef5b0bfa456c3b8b20248e1ac54182ee3ca41d0889ce5c7c8ff591d
 DIST Django-4.1.6.checksum.txt 2547 BLAKE2B 4aa35e26cd570f3091e3a56ef6afe866c372ce57839656d40520482f15e53c9c3ae79c77f82a440ff642ac45cfb0591c4a9f15c37c29feae08646db630b28cf8 SHA512 1cb20c349b4b4fadea4ad34bd9b60a61a8a2ac26a351c71d94756d84ef7e0c5348118bb58001dd3004ca73527023ed4c8fb2f6c840fa2457e8b6db45fa3ed7fb
 DIST Django-4.1.6.tar.gz 10496749 BLAKE2B 0c0dcc4ace84f201a8ed47e66f1378b583be92c7d02d928d8c3869322fafb5f7df67522fc35933dda65248416d06343be426513d6ca4133fc2b790d738df165e SHA512 83206551c84bd716d4adb198eb73c7c00dce073a64dd9dce0c70a50de47a932253a6878d54eec62b525f71111dc00ad5d08dd5b104c3988e7313c3571409329d
+DIST Django-4.1.7.checksum.txt 2554 BLAKE2B 5a82eca5edb5b5d90c629c6d42414725b32ed55fc137cfb3fc9c5bfd392dc0fcc3f6b99eea64a16a88002a521bf910464a6fe11d9079d68e056acded3432be38 SHA512 4244abf4e81aec1f8daa7815f57483963e94cf67571f0c2f6ab67507515c7f6f72f86412a17c8e1e73170e1ed7d3d4503c5adba36c66d0b8f015350c81348116
+DIST Django-4.1.7.tar.gz 10520415 BLAKE2B 88b66fea737f6fb1661a6987b9d6cecb84d58d675655a0ea5bed60ee28252edd11d8025498b7bc854b9c0c4814148bdc3bcdf59014dd040b5c424c3cd1711e46 SHA512 e34b0b05209297164d6cb84e7edf4740a2d638496c3107c06c0e773db292e9b02e6abbd8c3da347addaf17d9c9a56ef4873eb9edc5f1164e3d13d7f3ef083844
diff --git a/dev-python/django/django-4.1.7.ebuild b/dev-python/django/django-4.1.7.ebuild
new file mode 100644
index 000000000000..ae592a55a65f
--- /dev/null
+++ b/dev-python/django/django-4.1.7.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/asgiref-4[${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.5.2[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+		!!<dev-python/ipython-7.21.0-r1
+		!!=dev-python/ipython-7.22.0-r0
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}