dev-libs/libei: Version bump to 1.2.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 99 insertions, 0 deletions

diff --git a/dev-libs/libei/Manifest b/dev-libs/libei/Manifest
index f1890e5f34a6..5d4fbae9a190 100644
--- a/dev-libs/libei/Manifest
+++ b/dev-libs/libei/Manifest
@@ -1,2 +1,3 @@
 DIST libei-1.1.0.tar.bz2 169197 BLAKE2B 3f33b21a9876da533a6f52ecc2478065f4f3083f72880cf09f1bbeadcdcaed843e681e5d9fc8692ff667fe7262195caa272712b755997ca74a1b90f24492c08d SHA512 93525215cf896213e5f28581a1701cfccaf1ea07ae85744c01b6152ff29c2c9d6fd3afeeb8de5850cde915b540d3452bfe32c8c56bf780dd401da9947e28044b
+DIST libei-1.2.0.tar.bz2 174155 BLAKE2B 4b540cb79decd9785f67efa6fa76b984eb7ae2729dd49ac36e240b6a4feb4c54b34626dad93831c873861e3d3fd597c530e7eaaab0150890f0c952a9d75ee178 SHA512 c1d39c2c830df373ff5d7cc3eca330c2d771a26df6f2902d62f639a8a4db9af5370db4b9defe605721dd1f429eae68cbc4249792b3ae26b4c82d269f07a36732
 DIST munit-fbbdf1467eb0d04a6ee465def2e529e4c87f2118.tar.gz 27724 BLAKE2B 9670c9b7a0b5d9ee6ec8df2dea9e241b043964ecf1fa3f6060ad1d16c40ab6afe47f53c6d4a791003e101a0b363263b858e6e4e445f868292753dd1ee7f7e3ce SHA512 26b5599fd12be627a692823ebf496fa446be7ed04a1233fb42e0667c05109b0f804f76646e289ac660fc815baf45f77ec8caf0ff2ea7fb0b4f87f0038a2b971c
diff --git a/dev-libs/libei/libei-1.2.0.ebuild b/dev-libs/libei/libei-1.2.0.ebuild
new file mode 100644
index 000000000000..54379208a7ab
--- /dev/null
+++ b/dev-libs/libei/libei-1.2.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit meson python-any-r1
+
+DESCRIPTION="Library for Emulated Input, primarily aimed at the Wayland stack"
+HOMEPAGE="https://gitlab.freedesktop.org/libinput/libei"
+SRC_URI="https://gitlab.freedesktop.org/libinput/${PN}/-/archive/${PV}/${P}.tar.bz2"
+MUNIT_COMMIT="fbbdf1467eb0d04a6ee465def2e529e4c87f2118"
+SRC_URI+=" https://github.com/nemequ/munit/archive/${MUNIT_COMMIT}.tar.gz -> munit-${MUNIT_COMMIT}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="elogind systemd test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/libevdev-1.9.902
+	|| (
+		systemd? ( >=sys-apps/systemd-237 )
+		elogind? ( >=sys-auth/elogind-237 )
+		sys-libs/basu
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	$(python_gen_any_dep '
+		dev-python/attrs[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+	')
+	test? (
+		$(python_gen_any_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+			dev-python/pyyaml[${PYTHON_USEDEP}]
+			dev-python/structlog[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	if use test; then
+		python_has_version \
+			"dev-python/pytest[${PYTHON_USEDEP}]" \
+			"dev-python/python-dbusmock[${PYTHON_USEDEP}]" \
+			"dev-python/pyyaml[${PYTHON_USEDEP}]" \
+			"dev-python/structlog[${PYTHON_USEDEP}]" \
+			|| return 1
+	fi
+	python_has_version \
+		"dev-python/attrs[${PYTHON_USEDEP}]" \
+		"dev-python/jinja[${PYTHON_USEDEP}]" \
+		|| return 1
+}
+
+src_unpack() {
+	if [[ -n ${A} ]]; then
+		unpack ${A}
+		mv "${WORKDIR}"/munit-${MUNIT_COMMIT} "${WORKDIR}"/${P}/subprojects/munit || die
+		rm "${WORKDIR}"/${P}/subprojects/munit.wrap || die
+	fi
+}
+
+src_prepare() {
+	default
+
+	sed -i -e 's:^valgrind = .*:valgrind = disabler():g' test/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddocumentation=""
+		-Dliboeffis=enabled
+		$(meson_feature test tests)
+	)
+	if use systemd; then
+		emesonargs+=(-Dsd-bus-provider=libsystemd)
+	elif use elogind; then
+		emesonargs+=(-Dsd-bus-provider=libelogind)
+	else
+		emesonargs+=(-Dsd-bus-provider=basu)
+	fi
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# munit subproject is installed but not wanted
+	if use test; then
+		rm "${ED}"/usr/lib*/libmunit.so || die
+	fi
+}