proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

5 files changed, 176 insertions, 0 deletions

diff --git a/dev-libs/keybinder/Manifest b/dev-libs/keybinder/Manifest
new file mode 100644
index 000000000000..d9aac7d6ccae
--- /dev/null
+++ b/dev-libs/keybinder/Manifest
@@ -0,0 +1,2 @@
+DIST keybinder-0.3.0.tar.gz 377765 SHA256 42863ca0174d568a8c02c6fb243fee1681823825e8bcb1718c51611d8e9793bb SHA512 93ed88caa8246286907b9744383487391412b52be534cf085a6090c390bab181dc617721bb9216f29fd8314a40f65e27630d699ac6cb1657e0641a3d472eb22e WHIRLPOOL 5962e6a5cf96aeb7c4fdf920901f3ed461189fa9ce32bff427762a2f99b38fe4239b7129b5f669d46c256a4e7bf1fedf62ee966f05f65547e6921f364d8ff0d2
+DIST keybinder-3.0-0.3.0.tar.gz 346383 SHA256 982a6a5bc0fe1487862814b368e98211b9ec93fb5df3c9c0a88be526e0d2268e SHA512 6c5509b196fea848cda7e600edba2a59f7f65cbd7147e1d8ad2755aca8bb9b34ec68df1c90a456a7be800f049de0c2a4fc635adb60496a6aa32dea25f23dd86a WHIRLPOOL b378e7f2cc17cbe9bec9212df07e268377aea4979ab491d21092a6915fe219014686dbc188474daa2f21d1d48e016a657ae4d54d5c86407fc956c2c17d0398f0
diff --git a/dev-libs/keybinder/keybinder-0.3.0-r200.ebuild b/dev-libs/keybinder/keybinder-0.3.0-r200.ebuild
new file mode 100644
index 000000000000..177e8dbd7ad8
--- /dev/null
+++ b/dev-libs/keybinder/keybinder-0.3.0-r200.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+PYTHON_DEPEND="python? 2:2.6"
+
+inherit eutils python
+
+DESCRIPTION="A library for registering global keyboard shortcuts"
+HOMEPAGE="http://kaizer.se/wiki/keybinder/"
+SRC_URI="http://kaizer.se/publicfiles/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 arm ~hppa ~mips ppc ppc64 x86"
+IUSE="+introspection lua python"
+
+RDEPEND=">=x11-libs/gtk+-2.20:2
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXrender
+	introspection? ( dev-libs/gobject-introspection )
+	lua? ( >=dev-lang/lua-5.1 )
+	python? (
+		>=dev-python/pygobject-2.15.3:2
+		>=dev-python/pygtk-2.12
+		)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS="AUTHORS NEWS README"
+
+pkg_setup() {
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	>py-compile
+}
+
+src_configure() {
+	local myconf
+	use lua || myconf='--disable-lua'
+
+	econf \
+		$(use_enable introspection) \
+		$(use_enable python) \
+		${myconf} \
+		--with-html-dir=/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+	dosym /usr/share/doc/${PF}/html/${PN} /usr/share/gtk-doc/html/${PN}
+}
+
+pkg_postinst() {
+	use python && python_mod_optimize ${PN}
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup ${PN}
+}
diff --git a/dev-libs/keybinder/keybinder-0.3.0-r201.ebuild b/dev-libs/keybinder/keybinder-0.3.0-r201.ebuild
new file mode 100644
index 000000000000..6a1f95ca486c
--- /dev/null
+++ b/dev-libs/keybinder/keybinder-0.3.0-r201.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils python-single-r1
+
+DESCRIPTION="A library for registering global keyboard shortcuts"
+HOMEPAGE="http://kaizer.se/wiki/keybinder/"
+SRC_URI="http://kaizer.se/publicfiles/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86"
+IUSE="+introspection lua python"
+
+RDEPEND=">=x11-libs/gtk+-2.20:2
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXrender
+	introspection? ( dev-libs/gobject-introspection )
+	lua? ( >=dev-lang/lua-5.1 )
+	python? ( ${PYTHON_DEPS}
+		>=dev-python/pygobject-2.15.3:2[${PYTHON_USEDEP}]
+		>=dev-python/pygtk-2.12[${PYTHON_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS="AUTHORS NEWS README"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local myconf
+	use lua || myconf='--disable-lua'
+
+	econf \
+		$(use_enable introspection) \
+		$(use_enable python) \
+		${myconf}
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}
diff --git a/dev-libs/keybinder/keybinder-0.3.0-r300.ebuild b/dev-libs/keybinder/keybinder-0.3.0-r300.ebuild
new file mode 100644
index 000000000000..a115b63befcc
--- /dev/null
+++ b/dev-libs/keybinder/keybinder-0.3.0-r300.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+inherit eutils
+
+MY_P=${PN}-3.0-${PV}
+
+DESCRIPTION="A library for registering global keyboard shortcuts"
+HOMEPAGE="http://kaizer.se/wiki/keybinder/"
+SRC_URI="http://kaizer.se/publicfiles/${PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="3"
+KEYWORDS="amd64 arm ~hppa ~mips ppc ppc64 x86"
+IUSE="+introspection"
+
+RDEPEND="x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXrender
+	introspection? ( dev-libs/gobject-introspection )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS="AUTHORS NEWS README"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	econf \
+		$(use_enable introspection) \
+		--with-html-dir=/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+	dosym /usr/share/doc/${PF}/html/${PN}-3.0 /usr/share/gtk-doc/html/${PN}-3.0
+}
diff --git a/dev-libs/keybinder/metadata.xml b/dev-libs/keybinder/metadata.xml
new file mode 100644
index 000000000000..33b965f5bef7
--- /dev/null
+++ b/dev-libs/keybinder/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer>
+    <email>ssuominen@gentoo.org</email>
+    <name>Samuli Suominen</name>
+  </maintainer>
+  <use>
+    <flag name='introspection'>Use <pkg>dev-libs/gobject-introspection</pkg> for introspection</flag>
+  </use>
+</pkgmetadata>