dev-lang/yap: version bump

Package-Manager: Portage-3.0.28, Repoman-3.0.2
Signed-off-by: Keri Harris <keri@gentoo.org>

2 files changed, 103 insertions, 0 deletions

diff --git a/dev-lang/yap/Manifest b/dev-lang/yap/Manifest
index 5a02869cdcd7..7f9da1793200 100644
--- a/dev-lang/yap/Manifest
+++ b/dev-lang/yap/Manifest
@@ -1,2 +1,3 @@
 DIST YAP-6.3.4.tar.gz 11007893 BLAKE2B d8024fb68269bbb4f9a434e2be13b4a42aa250f7e6505ef8f6e4c76d50510e04e9a2985796ce66b1d426a877646eafeecb30774c353f5a820c32dc3cbdf20b1c SHA512 67884b98bbc564f23f88cbb1462127a47f3d0602ac347d1c8b0857e5d8ebd9d0ca28770229a6beb52493c6c3256b6cdf8dad25ed2963c64102093f70c4c20a3a
 DIST yap-6.3.4-gentoo-patchset-1.tar.gz 5544 BLAKE2B ea47ebff2d51bba1fda8aa54daa0c3236b4e3d910fea222cf19bfd92b781eca726ab38f8f92a1c5d019672dda234e58053a66728b0a620db3823245a0493792c SHA512 c6ac0bfdba1747496c433a393c9828962b3097c77cba6c7daefbda9b33d61a4c838e5de752307ac3b8965fd89928a4974366fe6da066f0a8a12cccde658c0d6e
+DIST yap-7.0.1.tar.gz 17500023 BLAKE2B 03705fc92574a23387681729410577f118e221011a51ce7e2d5d801453d55d9183dd359398cf7ca264ac526fa90f82f108d66e5172f3e1bbed51ea43c0ec9767 SHA512 f037f2bfc1e8263b25162f63604aac3173bf277b0e3bf61d0430109c42d45b159abb7298d6429800cf3121b9578ca5231b72eaf989a9c40e15c203044c30c428
diff --git a/dev-lang/yap/yap-7.0.1.ebuild b/dev-lang/yap/yap-7.0.1.ebuild
new file mode 100644
index 000000000000..b6d897df36f3
--- /dev/null
+++ b/dev-lang/yap/yap-7.0.1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit cmake flag-o-matic python-single-r1
+
+DESCRIPTION="YAP is a high-performance Prolog compiler"
+HOMEPAGE="http://www.dcc.fc.up.pt/~vsc/Yap/"
+SRC_URI="https://dev.gentoo.org/~keri/distfiles/yap/${P}.tar.gz"
+
+LICENSE="Artistic LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="R debug doc examples java mpi mysql odbc postgres python raptor readline sqlite static threads xml"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="dev-libs/libutf8proc
+	sys-libs/zlib
+	dev-libs/gmp:0
+	java? ( >=virtual/jdk-1.8:* )
+	mpi? ( virtual/mpi )
+	mysql? ( dev-db/mysql-connector-c:0= )
+	odbc? ( dev-db/unixODBC )
+	postgres? ( dev-db/postgresql:= )
+	R? ( dev-lang/R )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/wheel
+		dev-python/numpy
+	)
+	raptor? ( media-libs/raptor )
+	readline? ( sys-libs/readline:= sys-libs/ncurses:= )
+	sqlite? ( dev-db/sqlite )
+	xml? ( dev-libs/libxml2 )"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen[dot] )
+	java? ( dev-lang/swig )
+	python? ( dev-lang/swig )"
+
+src_prepare() {
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		eapply "${WORKDIR}"/${PV}
+	fi
+
+	sed -i \
+		-e "s|\(set ( libdir \"\${exec_prefix}\)/lib\")|\1/$(get_libdir)\")|" \
+		-e "s|\(set ( dlls \"\${exec_prefix}\)/lib/Yap\")|\1/$(get_libdir)/Yap\")|" \
+		-e "s|\(set ( docdir \"\${exec_prefix}/share/doc\)/Yap\")|\1/${PF}\")|" \
+		CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+
+	local mycmakeargs=(
+		-DWITH_YAP_STATIC=$(usex static)
+		-DWITH_THREADED_CODE=$(usex threads)
+		-DWITH_READLINE=$(usex readline)
+		-DWITH_MPI=$(usex mpi)
+		-DWITH_ODBC=$(usex odbc)
+		-DWITH_MYSQL=$(usex mysql)
+		-DWITH_POSTGRES=$(usex postgres)
+		-DWITH_SQLITE3=$(usex sqlite)
+		-DWITH_JAVA=$(usex java)
+		-DWITH_PYTHON=$(usex python)
+		-DWITH_SWIG=$(if use java || use python; then echo yes; else echo no; fi)
+		-DWITH_R=$(usex R)
+		-DWITH_Raptor2=$(usex raptor)
+		-DWITH_XML=$(usex xml)
+		-DWITH_XML2=$(if use raptor && use xml; then echo yes; else echo no; fi)
+		-DWITH_DOCS=$(usex doc)
+		-DWITH_CUDD=no
+		-DWITH_GECODE=no
+	)
+
+	use python && mycmakeargs+=( -DPython3_EXECUTABLE="${PYTHON}" )
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use doc; then
+		cmake_src_compile doxygen
+	fi
+}
+
+src_install() {
+	cmake_src_install
+
+	dodoc README
+	if use doc; then
+		dodoc -r "${BUILD_DIR}"/html
+	fi
+}