proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 82 insertions, 0 deletions

diff --git a/dev-db/recutils/recutils-1.5.ebuild b/dev-db/recutils/recutils-1.5.ebuild
new file mode 100644
index 000000000000..5017f95c8614
--- /dev/null
+++ b/dev-db/recutils/recutils-1.5.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+inherit autotools eutils elisp-common
+
+DESCRIPTION="Tools and libraries to access human-editable, plain text databases"
+HOMEPAGE="http://www.gnu.org/software/recutils/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="crypt curl emacs mdb nls static-libs"
+
+RDEPEND="sys-libs/readline
+	crypt? (
+		dev-libs/libgcrypt:0
+		dev-libs/libgpg-error
+	)
+	curl? ( net-misc/curl )
+	emacs? (
+		app-emacs/org-mode
+		virtual/emacs
+	)
+	mdb? (
+		app-office/mdbtools
+		dev-libs/glib:2
+	)
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-automagic.patch
+	epatch "${FILESDIR}"/${P}-glibc-2.16.patch
+
+	# Don't unconditionally install emacs files
+	sed -i -e "/^dist_lisp_DATA/d" etc/Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable crypt encryption) \
+		$(use_enable curl) \
+		$(use_enable mdb) \
+		$(use_enable nls) \
+		$(use_enable static-libs static)
+}
+
+src_compile() {
+	default
+
+	if use emacs ; then
+		elisp-compile etc/*.el || die
+	fi
+}
+
+src_install() {
+	default
+	use static-libs || find "${D}" -name '*.la' -delete
+
+	if use emacs ; then
+		elisp-install ${PN} etc/*.{el,elc} || die
+		elisp-site-file-install "${FILESDIR}"/${SITEFILE} || die
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}