app-shells/fzy: revbump, respect LDFLAGS

Closes: https://bugs.gentoo.org/719072
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

1 files changed, 45 insertions, 0 deletions

diff --git a/app-shells/fzy/fzy-1.0-r1.ebuild b/app-shells/fzy/fzy-1.0-r1.ebuild
new file mode 100644
index 000000000000..660ca21138e7
--- /dev/null
+++ b/app-shells/fzy/fzy-1.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils savedconfig toolchain-funcs
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/jhawthorn/fzy.git"
+else
+	SRC_URI="https://github.com/jhawthorn/${PN}/releases/download/${PV}/${P}.tar.gz"
+	KEYWORDS="amd64 arm arm64 ~ppc64 x86"
+fi
+
+DESCRIPTION="Fuzzy text selector (interactive grep) for console"
+HOMEPAGE="https://github.com/jhawthorn/fzy"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+PATCHES=( "${FILESDIR}"/1.0-cflags.patch )
+
+src_prepare() {
+	default
+	restore_config config.h
+	tc-export CC
+}
+
+src_install() {
+	local DOCS=( ALGORITHM.md CHANGELOG.md README.md )
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
+	dobin contrib/fzy-tmux
+	dobin contrib/fzy-dvtm
+	einstalldocs
+	save_config config.h
+}
+
+pkg_postinst() {
+	savedconfig_pkg_postinst
+	optfeature "opening search results in dvtm pane with provided ${EPREFIX}/usr/bin/fzy-dvtm" app-misc/dvtm
+	optfeature "opening search results in tmux pane with provided ${EPREFIX}/usr/bin/fzy-tmux" app-misc/tmux
+}