proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 71 insertions, 0 deletions

diff --git a/app-office/texmacs/texmacs-1.99.2.ebuild b/app-office/texmacs/texmacs-1.99.2.ebuild
new file mode 100644
index 000000000000..264522f65220
--- /dev/null
+++ b/app-office/texmacs/texmacs-1.99.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+inherit autotools eutils fdo-mime gnome2-utils
+
+MY_P=${P/tex/TeX}-src
+
+DESCRIPTION="Wysiwyg text processor with high-quality maths"
+HOMEPAGE="http://www.texmacs.org/"
+SRC_URI="ftp://ftp.texmacs.org/pub/TeXmacs/tmftp/source/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="imlib jpeg netpbm pdf qt4 svg spell"
+KEYWORDS="~alpha ~amd64 ~ppc ~x86 ~x86-interix ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	app-text/ghostscript-gpl
+	dev-scheme/guile:12[deprecated]
+	media-libs/freetype
+	x11-apps/xmodmap
+	x11-libs/libXext
+	virtual/latex-base
+	imlib? ( media-libs/imlib2 )
+	jpeg? ( || ( media-gfx/imagemagick media-gfx/jpeg2ps ) )
+	netpbm? ( media-libs/netpbm )
+	qt4? ( dev-qt/qtgui:4 )
+	spell? ( app-text/aspell )
+	svg? ( || ( media-gfx/inkscape gnome-base/librsvg:2 ) )
+"
+DEPEND="${RDEPEND}
+	x11-proto/xproto"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# respect LDFLAGS, bug #338459
+	epatch "${FILESDIR}"/${PN}-plugins-1.patch
+
+	# dont update mime and desktop databases and icon cache
+	epatch "${FILESDIR}"/${PN}-updates.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	econf --enable-optimize="${CXXFLAGS}" \
+		$(use_with imlib imlib2) \
+		$(use_enable qt4 qt) \
+		$(use_enable pdf pdf-renderer)
+}
+
+src_install() {
+	default
+	domenu "${FILESDIR}"/TeXmacs.desktop
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}