app-emulation/containers-storage: Bump to version 1.15.2

Package-Manager: Portage-2.3.80, Repoman-2.3.19
Signed-off-by: Zac Medico <zmedico@gentoo.org>

2 files changed, 61 insertions, 0 deletions

diff --git a/app-emulation/containers-storage/Manifest b/app-emulation/containers-storage/Manifest
index f453a080b8d4..c63a7e1b0b57 100644
--- a/app-emulation/containers-storage/Manifest
+++ b/app-emulation/containers-storage/Manifest
@@ -1 +1,2 @@
 DIST containers-storage-1.15.1.tar.gz 6037975 BLAKE2B e6d0d9adae829fd3d8cb40aa124b7149ee56ed13650b0dc57ba316ab2f03e754bdbb3e566c199b7768c612b159fa3051db39cd90127f4676255e452863aa7e24 SHA512 ea017e7dec840e5794f0ae61ebfc0cbf55b8de2c237286371eef3fd1808809e2bb149f08ba62126c741e0811839bf0af8f97bbda32e715132e42905f2ebd3a6c
+DIST containers-storage-1.15.2.tar.gz 6199303 BLAKE2B 76b950892d4a3016a6df2223c66d9720334205bb1c1b6d18f09b984df9c967391329a970d9d927206f37d4557fc6f4b6c366cb6f35711d2a7d8842f7e3bf7221 SHA512 b152e85e8ebdc5016955287c289390568865d60b2b034e5d32eaa3d11d775a12788465246ff7b75cd8a079758f5d2fd90bd1443191f6a089f54862951a26cdae
diff --git a/app-emulation/containers-storage/containers-storage-1.15.2.ebuild b/app-emulation/containers-storage/containers-storage-1.15.2.ebuild
new file mode 100644
index 000000000000..d094e8ef9e33
--- /dev/null
+++ b/app-emulation/containers-storage/containers-storage-1.15.2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit go-module
+
+KEYWORDS="~amd64"
+DESCRIPTION="containers/storage library"
+HOMEPAGE="https://github.com/containers/storage"
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+IUSE="btrfs +device-mapper test"
+EGO_PN="${HOMEPAGE#*//}"
+EGIT_COMMIT="v${PV}"
+SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+RDEPEND="
+	btrfs? ( sys-fs/btrfs-progs )
+	device-mapper? ( sys-fs/lvm2:= )"
+DEPEND="${RDEPEND}
+	dev-go/go-md2man
+	test? (
+		sys-fs/btrfs-progs
+		sys-fs/lvm2
+		sys-apps/util-linux
+	)"
+RESTRICT="test"
+
+S=${WORKDIR}/${P#containers-}
+
+src_prepare() {
+	default
+
+	sed -e 's:GO111MODULE=off:GO111MODULE=on:' -i Makefile || die
+
+	[[ -f hack/btrfs_tag.sh ]] || die
+	use btrfs || { echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
+		"hack/btrfs_tag.sh" || die; }
+
+	[[ -f hack/libdm_tag.sh ]] || die
+	use device-mapper || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_devicemapper" > \
+		"hack/libdm_tag.sh" || die; }
+}
+
+src_compile() {
+	export -n GOCACHE XDG_CACHE_HOME #678856
+	emake containers-storage docs
+}
+
+src_install() {
+	dobin "${PN}"
+	while read -r -d ''; do
+		mv "${REPLY}" "${REPLY%.1}" || die
+	done < <(find "${S}/docs" -name '*.[[:digit:]].1' -print0)
+	find "${S}/docs" -name '*.[[:digit:]]' -exec doman '{}' + || die
+}
+
+src_test() {
+	GOPATH="${S}" unshare -m emake local-test-unit || die
+}