app-crypt/eid-mw: update 5.1.15

Closes: https://bugs.gentoo.org/923375

Submitted-by: Vincent Hardy <vincent.hardy.be@gmail.com>
Signed-off-by: Amy Liffey <amynka@gentoo.org>

3 files changed, 136 insertions, 1 deletions

diff --git a/app-crypt/eid-mw/Manifest b/app-crypt/eid-mw/Manifest
index c331d5100830..4ec5af4820bf 100644
--- a/app-crypt/eid-mw/Manifest
+++ b/app-crypt/eid-mw/Manifest
@@ -1 +1,2 @@
 DIST eid-mw-5.1.13.tar.gz 15369717 BLAKE2B 99c70445abddd85ae7df917380a91d64ccefb7e3b73db4d2a5887a1dfc7d54e575ca0df5cbccdab41ce7ffb0648d6cb6c456da4f65ae2b0f0c4844ed2d5b343e SHA512 b7c024163d1eedb3cf5558be130fbe7fb3045c31bda541ed3402ac11514308c2ed9dd692972c8ddbe81a4923f67fb8205f761a0834abf65927991dade30e4ea4
+DIST eid-mw-5.1.15.tar.gz 16296281 BLAKE2B 12efbc884ff250d5497ace6b9670e4dac934a8aa87e2e77d4c083d3e0325c7b0a57dd137506f62a6e3ada57459b5b23e7d5e0d86a80616a64e05948560ce265b SHA512 4cf352ba912db6252f864430bacc895d29b478d3ec13ef3716089e5cb6019b2db2de08a99775dcd71a4ac9f13f3e3c6e1013f36bb2d458bbb0e851f7b45451e5
diff --git a/app-crypt/eid-mw/eid-mw-5.1.15.ebuild b/app-crypt/eid-mw/eid-mw-5.1.15.ebuild
new file mode 100644
index 000000000000..1c782e3b1ce9
--- /dev/null
+++ b/app-crypt/eid-mw/eid-mw-5.1.15.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools desktop gnome2-utils
+
+DESCRIPTION="Electronic Identity Card middleware supplied by the Belgian Federal Government"
+HOMEPAGE="https://eid.belgium.be"
+SRC_URI="https://codeload.github.com/fedict/${PN}/tar.gz/v${PV} -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="+dialogs +gtk p11-kit"
+
+RDEPEND=">=sys-apps/pcsc-lite-1.2.9
+	gtk? (
+		x11-libs/gdk-pixbuf[jpeg]
+		x11-libs/gtk+:3
+		dev-libs/libxml2
+		net-misc/curl[ssl]
+		net-libs/libproxy
+		>=app-crypt/pinentry-1.1.0-r4[gtk]
+	)
+	p11-kit? ( app-crypt/p11-kit )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+REQUIRED_USE="dialogs? ( gtk )"
+
+src_prepare() {
+	default
+
+	# Buggy internal versioning when autoreconf a tarball release.
+	# Weird numbering is required otherwise we get a seg fault in
+	# about-eid-mw program.
+	echo "${PV}-v${PV}" > .version
+
+	# See bug #862306
+	sed -i \
+		-e 's:PACKAGE_VERSION:MAINVERSION:' \
+		cardcomm/pkcs11/src/libbeidpkcs11.pc.in || die
+
+	# xpi module : we don't want it anymore
+	sed -i -e '/SUBDIRS/ s:plugins_tools/xpi ::' Makefile.am || die
+	sed -i -e '/plugins_tools\/xpi/ d' configure.ac || die
+
+	# hardcoded lsb_info
+	sed -i \
+		-e "s:get_lsb_info('i'):strdup(_(\"Gentoo\")):" \
+		-e "s:get_lsb_info('r'):strdup(_(\"n/a\")):" \
+		-e "s:get_lsb_info('c'):strdup(_(\"n/a\")):" \
+		plugins_tools/aboutmw/gtk/about-main.c || die
+
+	# Fix libdir for manifestdir
+	sed -i \
+		-e "/pkcs11_manifestdir/ s:prefix)/lib:libdir):" \
+		-e "/managed_storage_manifestdir/ s:prefix)/lib:libdir):" \
+		cardcomm/pkcs11/src/Makefile.am || die
+
+	# See bug #732994
+	sed -i \
+		-e '/LDFLAGS="/ s:$CPPFLAGS:$LDFLAGS:' \
+		configure.ac || die
+
+	# See bug #751472
+	eapply "${FILESDIR}/use-printf-in-Makefile.patch"
+
+	# See bug #811270 (remove uml build)
+	sed -i \
+		-e 's:cardlayer/uml::' \
+		cardcomm/pkcs11/src/Makefile.am || die
+	sed -i \
+		-e 's:uml::' \
+		plugins_tools/eid-viewer/Makefile.am || die
+
+	# See bug #923375
+	sed -i \
+		-e 's:C_Sign(NULL,:C_Sign(NULL_PTR,:' \
+		tests/unit/sign_state.c || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable dialogs) \
+		$(use_enable p11-kit p11kit) \
+		$(use_with gtk gtkvers 'detect') \
+		--with-gnu-ld \
+		--disable-static
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name '*.la' -delete || die
+	if use gtk; then
+		domenu plugins_tools/eid-viewer/eid-viewer.desktop
+		doicon plugins_tools/eid-viewer/gtk/eid-viewer.png
+	fi
+}
+
+pkg_postinst() {
+	if use gtk; then
+		gnome2_schemas_update
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+
+		local peimpl=$(eselect --brief --colour=no pinentry show)
+		case "${peimpl}" in
+		*gnome*|*qt*) ;;
+		*)	ewarn "The pinentry front-end currently selected is not supported by eid-mw."
+			ewarn "You may be prompted for your pin code in an inaccessible shell!!"
+			ewarn "Please select pinentry-gnome3 as default pinentry provider:"
+			ewarn " # eselect pinentry set pinentry-gnome3"
+		;;
+		esac
+	fi
+}
+
+pkg_postrm() {
+	if use gtk; then
+		gnome2_schemas_update
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+}
diff --git a/app-crypt/eid-mw/eid-mw-9999.ebuild b/app-crypt/eid-mw/eid-mw-9999.ebuild
index 567bbb9a1cd9..f514363c71c1 100644
--- a/app-crypt/eid-mw/eid-mw-9999.ebuild
+++ b/app-crypt/eid-mw/eid-mw-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -65,6 +65,11 @@ src_prepare() {
 		-e 's:uml::' \
 		plugins_tools/eid-viewer/Makefile.am || die
 
+	# See bug #923375
+	sed -i \
+		-e 's:C_Sign(NULL,:C_Sign(NULL_PTR,:' \
+		tests/unit/sign_state.c || die
+
 	eautoreconf
 }