app-admin/ansible-base: add 2.11.1

Was previously commited as ansible-2.11.1 (commit
b9e7796fb0d4dd759d28d9b80dd8c938c467ee99). Changes with respect to that
version : do not block ansible-base, handle the fact upstream now
calls this ansible-core rather than ansible-base, removed 3.7 from
PYTHON_COMPAT, do not override S when in live-ebuild mode.

Leaving the possible pkgmove from -base to -core to maintainers.

Signed-off-by: Marek Szuba <marecki@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/app-admin/ansible-base/Manifest b/app-admin/ansible-base/Manifest
index 964b037f8e2c..c7908ec569d2 100644
--- a/app-admin/ansible-base/Manifest
+++ b/app-admin/ansible-base/Manifest
@@ -1,2 +1,3 @@
 DIST ansible-base-2.10.10.tar.gz 5986488 BLAKE2B 5c793d25ac5a216d05e15f49cd447cbdfb2ef97c2881bca60be5c23e3245262e15304a63431704d8b69fff56594e25517c0e5e1f2641b3eca5ad6a1e76e4d7b3 SHA512 b599b498a20b77cd3346f5b865b5a0436cdd835af250e8cc4ed20d61ac6a4929bf4ceef9a95c6e7b8e825c5f513d33ea32b24661c58e2f1d285db0569d71fc1b
 DIST ansible-base-2.10.9.tar.gz 6039597 BLAKE2B de455cc402ae4c5c4acd6b1c3d3f2e16572d4a4e79c5f3e4151ec8b913a3be0cfbcb42e5743fe627b7aba9b0e6b004189960cd5a17ff46166cd033a952d3c560 SHA512 093514230a3f6680ddeda07c24e77c2e793475895f44da6e5dd68335341d6fefe10091a124cf84e18475257a099b39fd2c16e6fc0dae0bbaf2d26e70b09c277a
+DIST ansible-core-2.11.1.tar.gz 6148111 BLAKE2B 46b1553542adbebfb0b0756be99a81d20cce2978a59766c65632b40413a851ad3c9de12df67959c0557584c5209ecd4f3c94381ae0a1e6987bd3cfb237de5a85 SHA512 1362754dde0a88ca8f6323d87cc6f4bf5f93b189b8d45fcb435d3fb289c359da128e7688a92107ade2c54828d4c4deb3ded9e01e18d19c503306924aa189a381
diff --git a/app-admin/ansible-base/ansible-base-2.11.1.ebuild b/app-admin/ansible-base/ansible-base-2.11.1.ebuild
new file mode 100644
index 000000000000..466c8bf7fc59
--- /dev/null
+++ b/app-admin/ansible-base/ansible-base-2.11.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Model-driven deployment, config management, and command execution framework"
+HOMEPAGE="https://www.ansible.com/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ansible/ansible.git"
+	EGIT_BRANCH="devel"
+else
+	MY_PN="${PN/-base/-core}"
+	MY_P="${MY_PN}-${PV}"
+	SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~x64-macos"
+	S="${WORKDIR}"/${MY_P}
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="test"
+RESTRICT="test"
+
+RDEPEND="
+	dev-python/paramiko[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/httplib2[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/netaddr[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	dev-python/resolvelib[${PYTHON_USEDEP}]
+	net-misc/sshpass
+	virtual/ssh
+"
+DEPEND="
+	>=dev-python/packaging-16.6[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+		dev-python/passlib[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/unittest2[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)"
+
+python_compile() {
+	export ANSIBLE_SKIP_CONFLICT_CHECK=1
+	distutils-r1_python_compile
+}
+
+python_test() {
+	nosetests -d -w test/units -v --with-coverage --cover-package=ansible --cover-branches || die
+}