app-text/jabref: Fix antlr dependency now that Java 8 is addressed

This really depends on ANTLR 2 and 3. The fix applied in bug #547934
was somewhat bogus as 4 wasn't being used at all except for its
bundled version of 3. It is a non-issue now that 3 has a workaround
for Java 8.

Even though 3.2 depends on 2, it is unusual for a third party to
depend on both. Upstream actually uses 3.4 so 3.5 would be a closer
match but using 3.2 means you won't pull in two different versions of
stringtemplate.

Package-Manager: portage-2.2.26

1 files changed, 78 insertions, 0 deletions

diff --git a/app-text/jabref/jabref-2.10-r4.ebuild b/app-text/jabref/jabref-2.10-r4.ebuild
new file mode 100644
index 000000000000..ad8387b0c374
--- /dev/null
+++ b/app-text/jabref/jabref-2.10-r4.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+JAVA_ANT_REWRITE_CLASSPATH="true"
+
+inherit eutils java-pkg-2 java-ant-2 java-utils-2
+
+MY_PV="${PV/_beta/b}"
+
+DESCRIPTION="Java GUI for managing BibTeX and other bibliographies"
+HOMEPAGE="http://jabref.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/JabRef-${MY_PV}-src.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc"
+
+COMMON_DEP="
+	dev-java/antlr:0
+	dev-java/antlr:3
+	dev-java/fontbox:1.7
+	dev-java/jempbox:1.7
+	dev-java/log4j:0
+	dev-java/spin:0
+	dev-java/microba:0
+	>=dev-java/glazedlists-1.8.0:0
+	"
+
+DEPEND="
+	>=virtual/jdk-1.6
+	${COMMON_DEP}"
+
+RDEPEND="
+	>=virtual/jre-1.6
+	${COMMON_DEP}"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+java_prepare() {
+	# Remove bundled dependencies.
+	rm lib/antlr*.jar || die
+	rm lib/fontbox*.jar || die
+	rm lib/jempbox*.jar || die
+	rm lib/spin.jar || die
+	rm lib/microba.jar || die
+	rm lib/glazedlists*.jar || die
+
+	# Remove unjarlib target (do this only once we have removed all
+	# bundled dependencies in lib).
+	#sed -i -e 's:depends="build, unjarlib":depends="build":' build.xml
+
+	# Fix license file copy operation for microba bundled lib.
+	sed -i -e 's:^.*microba-license.*::' build.xml
+}
+
+src_compile() {
+	local EXTERNAL_JARS="antlr,antlr-3,fontbox-1.7,jempbox-1.7,log4j,spin,microba,glazedlists"
+	local CLASSPATH="$(java-pkg_getjars --with-dependencies ${EXTERNAL_JARS})"
+	eant \
+		-Dgentoo.classpath=${CLASSPATH} \
+		jars \
+		$(usex doc docs "")
+}
+
+src_install() {
+	java-pkg_newjar build/lib/JabRef-${MY_PV}.jar
+
+	use doc && java-pkg_dojavadoc build/docs/API
+	dodoc src/txt/README
+
+	java-pkg_dolauncher ${PN} --main net.sf.jabref.JabRef
+	newicon src/images/JabRef-icon-48.png JabRef-icon.png
+	make_desktop_entry ${PN} JabRef JabRef-icon Office
+}