dev-python/flask: Bump to 1.1

Also fix dependencies for -9999

Package-Manager: Portage-2.3.72, Repoman-2.3.17
Signed-off-by: Patrick Lauer <patrick@gentoo.org>

3 files changed, 60 insertions, 2 deletions

diff --git a/dev-python/flask/Manifest b/dev-python/flask/Manifest
index 4ac9c5ef2b76..a02e1de56ff1 100644
--- a/dev-python/flask/Manifest
+++ b/dev-python/flask/Manifest
@@ -1,3 +1,4 @@
 DIST Flask-0.12.2.tar.gz 548510 BLAKE2B bd92d0e7e6ff36d371ffd958708517d16e41d1475af9153bf3d5234c33aa5c0ab415cbd254b711731cf8cffddac94b475f62d9fff2f9fe756b0fa30bb36d4343 SHA512 c00bb807e8fbc943e23a3721acf5b04320e7a58d658bca46bdf83a345b4c4d5729accae338505e134f01bc908adec9555fd94e8c87ef6f0367e6037215c06319
 DIST Flask-1.0.2.tar.gz 644534 BLAKE2B dd024f6f7a68691c759e3fd494a9482c4ab5216b5c7486fc1717346f953678c3198deedd657e7ddd3a5deff57ce31b1afdc40ef2ba9cc2fbed48f3afc223f6d0 SHA512 0ddf5d8bb0b0ae61f990096dffe3cf02744d7986015d05ae2cc09dfe0def17df44e2a4c58e330d17c7bd8c3eb74014dee5e2edef6e300b8e4ed756c251938f52
 DIST Flask-1.0.4.tar.gz 615497 BLAKE2B 4141de3754a8ce42c6978a72da80c991d13415a19946180f5fd8f08a1827209be605ec10283b78841bee94c5a2036b8e6083187a3e68c188fde93cb702a6d645 SHA512 2ed45ebdef80fe354a0a221f991560e17c442550f667fb76dd9c9631428fe8b6686127504f4ee81fcc6748f99cd376bed7a1ff4e0a9ae913cd70c9f5f4ac1c61
+DIST Flask-1.1.1.tar.gz 625458 BLAKE2B aea56848dd1f8bb2d96059adf069f8d19c55395e5dd0d98bf4e89c7d1b54241f1f476cbf7fdb91a2390cb5438a3bd7a5bdb58383f2a196b042e90f272cb39e53 SHA512 d4e6304bdb2e20deda5b9800dc9ebeabf0442528d6cef2d15416129c151b25ab32c41460939f64fb72b15ead8d4e9bcea5694039323d080d279bfba2f6266178
diff --git a/dev-python/flask/flask-1.1.1.ebuild b/dev-python/flask/flask-1.1.1.ebuild
new file mode 100644
index 000000000000..80cc931b35be
--- /dev/null
+++ b/dev-python/flask/flask-1.1.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+HOMEPAGE="https://github.com/pallets/flask/"
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/mitsuhiko/flask.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc examples test"
+
+RDEPEND="dev-python/click[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/itsdangerous[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.15[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "s/ 'sphinx.ext.intersphinx',//" -i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	PYTHONPATH=${S}/examples/flaskr:${S}/examples/minitwit${PYTHONPATH:+:${PYTHONPATH}} \
+		py.test -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	use doc && HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/flask/flask-9999.ebuild b/dev-python/flask/flask-9999.ebuild
index 6b340034d517..80cc931b35be 100644
--- a/dev-python/flask/flask-9999.ebuild
+++ b/dev-python/flask/flask-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -28,7 +28,7 @@ RDEPEND="dev-python/click[${PYTHON_USEDEP}]
 	dev-python/blinker[${PYTHON_USEDEP}]
 	dev-python/itsdangerous[${PYTHON_USEDEP}]
 	>=dev-python/jinja-2.10[${PYTHON_USEDEP}]
-	>=dev-python/werkzeug-0.14[${PYTHON_USEDEP}]"
+	>=dev-python/werkzeug-0.15[${PYTHON_USEDEP}]"
 DEPEND="${RDEPEND}
 	dev-python/setuptools[${PYTHON_USEDEP}]
 	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )