sys-kernel/gentoo-kernel-bin: add 5.14.8-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index ff802b4d79c9..382139e761ac 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -33,6 +33,7 @@ DIST gentoo-kernel-5.14.7-1.amd64.xpak 68031586 BLAKE2B 7cc01200f01a93daf5f0c84b
 DIST gentoo-kernel-5.14.7-1.arm64.xpak 63383693 BLAKE2B d8780cdd6306f36530d82b9a5b6a74e1d2caf9c4e9db31d6816020bc9415fe92891e418dd08f89628f3d36189c84f97c10b570091c2d1a94a494f37a21286706 SHA512 90ef111ef0ef68dd362c458c9e6ea15959713118787ebd8c68492bd204da83a212e5def456fd550c3f175565c262581855599adeb34692c65f54c2f2d7f1d06c
 DIST gentoo-kernel-5.14.7-1.x86.xpak 59157603 BLAKE2B 2c8d5d3786f9b2aa77d0ac7eb4b3dff0d534bebbd974ec43b8b1e7e9322d3a1b9db0554ebb3bf6943f00673e087bb1067f14d341836012bb46774e5b194f1cf5 SHA512 af337483437a9819d16235e9641cb3f9893e140091e31a06ccb1015a6e946189defb5b2d2d12afd19dffaef1828a2d101b01798f107457a53a93ada2d063f023
 DIST gentoo-kernel-5.14.8-1.amd64.xpak 68070862 BLAKE2B 6f98d2eb2affd7705b5886f2e9c24c0e006cc82ee89134c248a94bca41f4d3a6412f1e4b037fb8fe92950cf02660b7e75f67eaa64484e4808115cdd2f7eafa6a SHA512 d5accd546033d2ad832cf6e21e5dd780c1e1c8c60d7a568cf796cd7e95c52b244f559886c728d54351b9f3d8054867cd57b0f28ae43d840bb83391bb2358a698
+DIST gentoo-kernel-5.14.8-1.arm64.xpak 63311629 BLAKE2B 0bdc32d597f413bc2b30e704a599c0edf55ce5437772ed886da5a6787ddcce5c6eebc699860df41536a8449f5442f56ca8ff1d10a5bd3f142c9f1092fb6c02cf SHA512 2e27ea733f68d49afe2fe5bc654e9ce4125ad87bad4a98936473c1e4d9c8b59374c226c4cc397f52463371b41cacc59d274bda421842a080f0804739b8c72fbc
 DIST gentoo-kernel-5.14.8-1.x86.xpak 59162488 BLAKE2B 12f31c41617eacce67f9ee960c9959fc7e19f074dd31bfa080eacde89ba6215136dee0a00f7c0127ab0f8fcd4896c24a132333ec64845c0756ba89c6d47a7e44 SHA512 6e230c100fb83e144ab91e02697800286ad331ea1a3fedb370dc1c3615c2dee0ac47a9438b97dc38c9fc6cdc44d54fe18e721fe8cb47e9f5552dd9edd154d61a
 DIST gentoo-kernel-5.14.9-1.amd64.xpak 68066846 BLAKE2B da508a4e8e96dcc0ea331f9c798808e4b0047cce6342994b5a2248d5becf1fd010e0ee8d7dd3427e4ead92359b9c1b92e2085d91fe08b5ee6c73f9622ec58bb2 SHA512 e5a90c9ed4a3192e4ecf283bf76efa1a5e39af1f20eb18e9494dcfb8d2ef88ab23e4bec53ec81c664c0cbd47a22eb8d6907b21e970ec7b41e4ed97b4cf3b2c83
 DIST gentoo-kernel-5.14.9-1.x86.xpak 59163747 BLAKE2B 23feb5d1d74c8ae1e3f4a66b215e887e4bfe700d80bbe8c75cabac9632808193e8a29f7c43baa2376279eb3b4fc9be530528731f02ba94778fd2e087e216d9ee SHA512 90492421abd0ed5a026c8cacbf64050e2ad18b7305ef96131964a6203e32d278ef7f1392ad76dab12ff3057c17046d44b371c567d8ef4ea18e0c2678c9208414
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.8-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.8-r1.ebuild
new file mode 100644
index 000000000000..c4534b7e4c4d
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.8-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+		-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}