net-ftp/filezilla: Bump to version 3.54.1

Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 72 insertions, 0 deletions

diff --git a/net-ftp/filezilla/Manifest b/net-ftp/filezilla/Manifest
index 3ae227a9e467..fbba9264e706 100644
--- a/net-ftp/filezilla/Manifest
+++ b/net-ftp/filezilla/Manifest
@@ -1 +1,2 @@
 DIST FileZilla_3.53.1_src.tar.bz2 4844262 BLAKE2B 1ae9bab7b3812df106340a2267d5634c3e3e3078a5fbb3dcbf526c28ea5bfefe619e380b739533754ec9f4e200d08a398d6ebe0c984a7b18679f0165f3a03e29 SHA512 85109c68c9acaf2d3fb7d2ed98bdeae636cc359993535484ca404bd34e8287927628e255364bdb03681fcc47bff02423e954fd304b2e304bf18efaf2c0784eaa
+DIST FileZilla_3.54.1_src.tar.bz2 4847815 BLAKE2B 86d219e6c26c15bfd5597e486fafc7892aa3d085d62e6780fb0518a0e10f984a2e7f562666149fd8650f3cd00ad86901daf459095c542460f3bc229c047fa3e2 SHA512 d41b9fb303c11c81ceb0577fa5d40d6f5d9d1dc70a6a6bb6dac5c4cb7f8fc22cf06c2cf2e7415d922d11d5d4262832db89647acc34fa9a6cd92105b7700901df
diff --git a/net-ftp/filezilla/filezilla-3.54.1.ebuild b/net-ftp/filezilla/filezilla-3.54.1.ebuild
new file mode 100644
index 000000000000..2a533aafc612
--- /dev/null
+++ b/net-ftp/filezilla/filezilla-3.54.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+WX_GTK_VER="3.0-gtk3"
+
+inherit autotools flag-o-matic wxwidgets xdg
+
+MY_PV="${PV/_/-}"
+MY_P="FileZilla_${MY_PV}"
+
+DESCRIPTION="FTP client with lots of useful features and an intuitive interface"
+HOMEPAGE="https://filezilla-project.org/"
+SRC_URI="https://download.filezilla-project.org/client/${MY_P}_src.tar.bz2"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="dbus nls test"
+RESTRICT="!test? ( test )"
+
+# pugixml 1.7 minimal dependency is for c++11 proper configuration
+RDEPEND="
+	>=app-eselect/eselect-wxwidgets-0.7-r1
+	>=dev-libs/nettle-3.1:=
+	>=dev-db/sqlite-3.7
+	>=dev-libs/libfilezilla-0.28.0:=
+	>=dev-libs/pugixml-1.7
+	>=net-libs/gnutls-3.5.7
+	>=x11-libs/wxGTK-3.0.4:${WX_GTK_VER}[X]
+	x11-misc/xdg-utils
+	dbus? ( sys-apps/dbus )"
+DEPEND="${RDEPEND}
+	test? ( >=dev-util/cppunit-1.13.0 )"
+BDEPEND="
+	virtual/pkgconfig
+	>=sys-devel/libtool-1.4
+	nls? ( >=sys-devel/gettext-0.11 )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.22.1-debug.patch
+	"${FILESDIR}"/${PN}-3.47.0-metainfo.patch
+	"${FILESDIR}"/${PN}-3.47.0-disable-shellext_conf.patch
+	"${FILESDIR}"/${PN}-3.52.2-slibtool.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	setup-wxwidgets
+
+	local myeconfargs=(
+		--disable-autoupdatecheck
+		--with-pugixml=system
+		$(use_enable nls locales)
+		$(use_with dbus)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}