From ee46b9509441b9c166f1437ddea84908887d5ea1 Mon Sep 17 00:00:00 2001
From: Ionen Wolkens <ionen@gentoo.org>
Date: Fri, 20 Jan 2023 17:36:04 -0500
Subject: media-gfx/imv: drop live ebuild

Going ahead with doing this until upstream situation improves
(upstream put package up for adoption and not much point in
expecting anything from the current live ebuild).

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
---
 media-gfx/imv/imv-9999.ebuild | 87 -------------------------------------------
 1 file changed, 87 deletions(-)
 delete mode 100644 media-gfx/imv/imv-9999.ebuild

(limited to 'media-gfx')

diff --git a/media-gfx/imv/imv-9999.ebuild b/media-gfx/imv/imv-9999.ebuild
deleted file mode 100644
index 2aca12fa827d..000000000000
--- a/media-gfx/imv/imv-9999.ebuild
+++ /dev/null
@@ -1,87 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit meson xdg
-
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://git.sr.ht/~exec64/imv/"
-else
-	SRC_URI="https://git.sr.ht/~exec64/imv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-	S="${WORKDIR}/${PN}-v${PV}"
-	KEYWORDS="~amd64 ~x86"
-fi
-
-DESCRIPTION="Minimal image viewer designed for tiling window manager users"
-HOMEPAGE="https://sr.ht/~exec64/imv/"
-
-LICENSE="MIT-with-advertising"
-SLOT="0"
-IUSE="+X +freeimage gif heif icu jpeg png svg test tiff wayland"
-REQUIRED_USE="|| ( X wayland )"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-libs/glib:2
-	dev-libs/inih
-	media-libs/libglvnd[X?]
-	x11-libs/cairo
-	x11-libs/libxkbcommon[X?]
-	x11-libs/pango
-	X? (
-		x11-libs/libX11
-		x11-libs/libxcb:=
-	)
-	freeimage? ( media-libs/freeimage )
-	gif? ( media-libs/libnsgif )
-	heif? ( media-libs/libheif:= )
-	icu? ( dev-libs/icu:= )
-	!icu? ( >=dev-libs/libgrapheme-2:= )
-	jpeg? ( media-libs/libjpeg-turbo:= )
-	png? ( media-libs/libpng:= )
-	svg? ( >=gnome-base/librsvg-2.44:2 )
-	tiff? ( media-libs/tiff:= )
-	wayland? ( dev-libs/wayland )
-	!sys-apps/renameutils"
-DEPEND="
-	${RDEPEND}
-	X? ( x11-base/xorg-proto )
-	test? ( dev-util/cmocka )"
-BDEPEND="
-	app-text/asciidoc
-	wayland? ( dev-util/wayland-scanner )"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-4.3.1_p20211221-animated-gif.patch
-)
-
-src_prepare() {
-	default
-
-	# if wayland-only, don't automagic on libGL and force libOpenGL
-	if ! use X; then
-		sed -i "/dependency('gl'/{s/'gl'/'opengl'/;s/false/true/}" meson.build || die
-	fi
-
-	# glu isn't used by anything
-	sed -i "/dependency('glu')/d" meson.build || die
-}
-
-src_configure() {
-	local emesonargs=(
-		$(meson_feature freeimage)
-		$(meson_feature gif libnsgif)
-		$(meson_feature heif libheif)
-		$(meson_feature jpeg libjpeg)
-		$(meson_feature png libpng)
-		$(meson_feature svg librsvg)
-		$(meson_feature test)
-		$(meson_feature tiff libtiff)
-		-Dunicode=$(usex icu{,} grapheme)
-		-Dwindows=$(usex X $(usex wayland all x11) wayland)
-	)
-
-	meson_src_configure
-}
-- 
cgit v1.2.3-65-gdbad