From 4507381ccaf4296f4acee179b841fa1e83006993 Mon Sep 17 00:00:00 2001
From: Rémi Cardona <remi@gentoo.org>
Date: Thu, 16 Jan 2020 00:10:24 +0100
Subject: dev-libs/gom: bump to 0.3.3
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Brought over from the gnome overlay with the following changes:

- port to EAPI=7
- simplify meson/python-r1 interactions
- remove broken DESTDIR argument when calling meson_src_install
- properly generate .pyc files (QA warning)

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Rémi Cardona <remi@gentoo.org>
---
 dev-libs/gom/gom-0.3.3.ebuild | 65 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 dev-libs/gom/gom-0.3.3.ebuild

(limited to 'dev-libs/gom/gom-0.3.3.ebuild')

diff --git a/dev-libs/gom/gom-0.3.3.ebuild b/dev-libs/gom/gom-0.3.3.ebuild
new file mode 100644
index 000000000000..9a9ca3dfec62
--- /dev/null
+++ b/dev-libs/gom/gom-0.3.3.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+GCONF_DEBUG="yes"
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit gnome.org gnome2-utils meson python-r1
+
+DESCRIPTION="GObject to SQLite object mapper library"
+HOMEPAGE="https://wiki.gnome.org/Projects/Gom"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc +introspection test"
+
+RDEPEND="
+	>=dev-db/sqlite-3.7:3
+	>=dev-libs/glib-2.36:2
+	introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
+	${PYTHON_DEPS}
+	>=dev-python/pygobject-3.16:3[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	>=dev-util/intltool-0.40.0
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( x11-libs/gdk-pixbuf:2 )
+"
+# TODO: make gdk-pixbuf properly optional with USE=test
+
+pkg_setup() {
+	python_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection enable-introspection)
+		$(meson_use doc enable-gtk-doc)
+	)
+
+	python_foreach_impl meson_src_configure
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_install() {
+	docinto examples
+	dodoc examples/*.py
+
+	installing() {
+		meson_src_install
+		python_optimize
+	}
+	python_foreach_impl installing
+}
+
+src_test() {
+	# tests may take a long time
+	python_foreach_impl meson_src_test
+}
-- 
cgit v1.2.3-65-gdbad