From 4e6945a5f8f316a51bb46c95aee23f0f72e73bda Mon Sep 17 00:00:00 2001
From: Yixun Lan <dlan@gentoo.org>
Date: Thu, 4 Jun 2020 10:43:54 +0800
Subject: app-backup/snapper: fix the missing dependency

missing app-text/docbook-xsl-stylesheets will
cause fail to build the doc of snapper.

thanks 'Stefan Langenmaier' for testing/fixing

Closes: https://bugs.gentoo.org/726400
Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Yixun Lan <dlan@gentoo.org>
---
 app-backup/snapper/snapper-0.8.9-r1.ebuild | 81 ++++++++++++++++++++++++++++++
 app-backup/snapper/snapper-0.8.9.ebuild    | 80 -----------------------------
 2 files changed, 81 insertions(+), 80 deletions(-)
 create mode 100644 app-backup/snapper/snapper-0.8.9-r1.ebuild
 delete mode 100644 app-backup/snapper/snapper-0.8.9.ebuild

(limited to 'app-backup/snapper')

diff --git a/app-backup/snapper/snapper-0.8.9-r1.ebuild b/app-backup/snapper/snapper-0.8.9-r1.ebuild
new file mode 100644
index 000000000000..5a5593c28464
--- /dev/null
+++ b/app-backup/snapper/snapper-0.8.9-r1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd bash-completion-r1
+
+DESCRIPTION="Command-line program for btrfs and lvm snapshot management"
+HOMEPAGE="http://snapper.io/"
+SRC_URI="https://github.com/openSUSE/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="lvm pam xattr"
+
+RDEPEND="dev-libs/boost:=[threads]
+	dev-libs/libxml2
+	dev-libs/icu:=
+	sys-apps/acl
+	sys-apps/dbus
+	sys-apps/util-linux
+	>=sys-fs/btrfs-progs-3.17.1
+	sys-libs/zlib
+	virtual/libintl
+	lvm? ( sys-fs/lvm2 )
+	pam? ( sys-libs/pam )
+	xattr? ( sys-apps/attr )"
+
+DEPEND="${RDEPEND}
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/cron-confd.patch
+)
+
+src_prepare() {
+	default
+
+	sed -e "s,/usr/lib/systemd/system,$(systemd_get_systemunitdir),g" \
+		-i data/Makefile.* \
+		|| die "Failed to fix systemd services and timers installation path"
+	eautoreconf
+}
+
+src_configure() {
+	# ext4 code does not work anymore
+	# snapper does not build without btrfs
+	local myeconfargs=(
+		--with-conf="/etc/conf.d"
+		--disable-zypp
+		--enable-rollback
+		--disable-ext4
+		--enable-btrfs
+		$(use_enable lvm)
+		$(use_enable pam)
+		$(use_enable xattr xattrs)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	# Existing configuration file required to function
+	keepdir /etc/snapper/configs
+	newconfd data/sysconfig.snapper snapper
+	find "${D}" -name '*.la' -delete || die
+	newbashcomp "${FILESDIR}"/${PN}.bash ${PN}
+}
+
+pkg_postinst() {
+	elog "In order to use Snapper, you need to set up"
+	elog "at least one config first. To do this, run:"
+	elog "snapper create-config <subvolume>"
+	elog "For more information, see man (8) snapper or"
+	elog "http://snapper.io/documentation.html"
+}
diff --git a/app-backup/snapper/snapper-0.8.9.ebuild b/app-backup/snapper/snapper-0.8.9.ebuild
deleted file mode 100644
index 9b77e973fc03..000000000000
--- a/app-backup/snapper/snapper-0.8.9.ebuild
+++ /dev/null
@@ -1,80 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools systemd bash-completion-r1
-
-DESCRIPTION="Command-line program for btrfs and lvm snapshot management"
-HOMEPAGE="http://snapper.io/"
-SRC_URI="https://github.com/openSUSE/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="lvm pam xattr"
-
-RDEPEND="dev-libs/boost:=[threads]
-	dev-libs/libxml2
-	dev-libs/icu:=
-	sys-apps/acl
-	sys-apps/dbus
-	sys-apps/util-linux
-	>=sys-fs/btrfs-progs-3.17.1
-	sys-libs/zlib
-	virtual/libintl
-	lvm? ( sys-fs/lvm2 )
-	pam? ( sys-libs/pam )
-	xattr? ( sys-apps/attr )"
-
-DEPEND="${RDEPEND}
-	dev-libs/libxslt
-	sys-devel/gettext
-	virtual/pkgconfig"
-
-PATCHES=(
-	"${FILESDIR}"/cron-confd.patch
-)
-
-src_prepare() {
-	default
-
-	sed -e "s,/usr/lib/systemd/system,$(systemd_get_systemunitdir),g" \
-		-i data/Makefile.* \
-		|| die "Failed to fix systemd services and timers installation path"
-	eautoreconf
-}
-
-src_configure() {
-	# ext4 code does not work anymore
-	# snapper does not build without btrfs
-	local myeconfargs=(
-		--with-conf="/etc/conf.d"
-		--disable-zypp
-		--enable-rollback
-		--disable-ext4
-		--enable-btrfs
-		$(use_enable lvm)
-		$(use_enable pam)
-		$(use_enable xattr xattrs)
-	)
-
-	econf "${myeconfargs[@]}"
-}
-
-src_install() {
-	default
-	# Existing configuration file required to function
-	keepdir /etc/snapper/configs
-	newconfd data/sysconfig.snapper snapper
-	find "${D}" -name '*.la' -delete || die
-	newbashcomp "${FILESDIR}"/${PN}.bash ${PN}
-}
-
-pkg_postinst() {
-	elog "In order to use Snapper, you need to set up"
-	elog "at least one config first. To do this, run:"
-	elog "snapper create-config <subvolume>"
-	elog "For more information, see man (8) snapper or"
-	elog "http://snapper.io/documentation.html"
-}
-- 
cgit v1.2.3-65-gdbad