1 files changed, 61 insertions, 0 deletions
diff --git a/kde-apps/ksystemlog/ksystemlog-19.08.2.ebuild b/kde-apps/ksystemlog/ksystemlog-19.08.2.ebuild
new file mode 100644
index 000000000000..66a4582b810b
--- /dev/null
+++ b/kde-apps/ksystemlog/ksystemlog-19.08.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="System log viewer by KDE"
+HOMEPAGE="https://kde.org/applications/system/ksystemlog/"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="systemd"
+
+# bug 378101
+RESTRICT+=" test"
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtprintsupport)
+	$(add_qt_dep qtwidgets)
+	systemd? ( sys-apps/systemd )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	kde5_src_prepare
+
+	if use test; then
+		# beat this stupid test into shape: the test files contain no year, so
+		# comparison succeeds only in 2007 !!!
+		local theyear=$(date +%Y)
+		einfo Setting the current year as ${theyear} in the test files
+		sed -e "s:2007:${theyear}:g" -i tests/systemAnalyzerTest.cpp || die
+
+		# one test consistently fails, so comment it out for the moment
+		sed -e "s:systemAnalyzerTest:# dont run systemAnalyzerTest:g" \
+			-i ksystemlog/tests/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package systemd Journald)
+	)
+	kde5_src_configure
+}