games-simulation/corsix-th: Version bump to 0.63, EAPI 7

Closes: https://bugs.gentoo.org/714878
Package-Manager: Portage-2.3.96, Repoman-2.3.20
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/games-simulation/corsix-th/Manifest b/games-simulation/corsix-th/Manifest
index eb924872465e..96a770db1b7f 100644
--- a/games-simulation/corsix-th/Manifest
+++ b/games-simulation/corsix-th/Manifest
@@ -1 +1,2 @@
 DIST corsix-th-0.62.tar.gz 3461932 BLAKE2B 5497cc944e51d80216f2b159249268a056193ef48837aa887d9ab8e7fd2e3134ae6f9517a6b2bd9293a97543dcc91dd76d5ce22e212f13dd7c02a79318c7ede6 SHA512 64fe4a6124cbf2e76934f2c081641119ded7292ce89124dee26c99c1d99f1979f9c520e73a403f0de751072bfd049a809773d6a919b7240b8a6e6b7aa1361bf0
+DIST corsix-th-0.63.tar.gz 4040119 BLAKE2B a700264c21377d53fb031c57428e5a50bbef426f32a3cd8bc4f83174a7f12b76d72050885ae257a6017a03f2f9611106cf9226c606ef726c1220b997eacbc5f1 SHA512 73a170bbf3da0e11ffe30fcbafb80f9e3852ce992dd6ecae2a2da332b9d4927a98efb0208e2056918a4100db54d1bdc564454cadae370cfab87625ca3f9889fd
diff --git a/games-simulation/corsix-th/corsix-th-0.63.ebuild b/games-simulation/corsix-th/corsix-th-0.63.ebuild
new file mode 100644
index 000000000000..5364f218f86d
--- /dev/null
+++ b/games-simulation/corsix-th/corsix-th-0.63.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+MY_PN="CorsixTH"
+MY_PV="$(ver_rs 2 -)"
+
+DESCRIPTION="Open source clone of Theme Hospital"
+HOMEPAGE="http://corsixth.com"
+SRC_URI="https://github.com/${MY_PN}/${MY_PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc libav +midi +sound +truetype +videos"
+
+RDEPEND="
+	>=dev-lang/lua-5.1:0
+	>=dev-lua/luafilesystem-1.5
+	>=dev-lua/lpeg-0.9
+	>=dev-lua/luasocket-3.0_rc1-r4
+	media-libs/libsdl2[opengl,video]
+	sound? ( media-libs/sdl2-mixer[midi?] )
+	truetype? ( >=media-libs/freetype-2.5.3:2 )
+	videos? (
+		!libav? ( >=media-video/ffmpeg-2.2.3:0= )
+		libav? ( >=media-video/libav-11.1:0= )
+	)
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		 app-doc/doxygen[dot]
+		 >=dev-lang/lua-5.1:0
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.62-gcc-10.patch
+)
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_AUDIO=$(usex sound)
+		-DWITH_FREETYPE2=$(usex truetype)
+		-DWITH_LIBAV=$(usex libav)
+		-DWITH_MOVIES=$(usex videos)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_src_compile doc
+}
+
+src_install() {
+	cmake_src_install
+	dodoc {changelog,CONTRIBUTING}.txt
+
+	docinto html
+	use doc && dodoc -r "${BUILD_DIR}"/doc/*
+}