dev-libs/libnsfb: drop netsurf eclass

Signed-off-by: Virgil Dupras <vdupras@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

3 files changed, 50 insertions, 46 deletions

diff --git a/dev-libs/libnsfb/Manifest b/dev-libs/libnsfb/Manifest
index f01b8e24c4a6..3344cf30ba90 100644
--- a/dev-libs/libnsfb/Manifest
+++ b/dev-libs/libnsfb/Manifest
@@ -1,2 +1 @@
 DIST libnsfb-0.2.0-src.tar.gz 82322 BLAKE2B d805478728015663b4bf9c8de018bda33dcd84a7ace7246c450a7c31cc3358f834ade21ac1df9f0ca0e4dcea1138369cc3cd9ac468ebb484cce139d4bc89441e SHA512 b90eca76c8dcb22e554e13b5bea4268e5c9fc6e4711bafa5acbed92cc83513c3a3965208b3956de250fb3013cc3db6a33922ded471fa7a24bde97f748d2212c5
-DIST netsurf-buildsystem-1.7.tar.gz 38597 BLAKE2B d0981ef282ac0d93d81a1a6a6bee1fc2a0151c962be6ce2900a67843ba8ebc67e00508cded2a7375f6bbe0d45572690f127872936a282de80eb08655ac571603 SHA512 f6a46ac25f41e695ec13d7b2b564250c4cc44a40a688904eb17aa4b547c2df0102cc0effb7a23a2ffa6b9178ae5cf452b63980caf26e06e479168c85803f1e58
diff --git a/dev-libs/libnsfb/libnsfb-0.2.0-r1.ebuild b/dev-libs/libnsfb/libnsfb-0.2.0-r1.ebuild
new file mode 100644
index 000000000000..b94247e21dac
--- /dev/null
+++ b/dev-libs/libnsfb/libnsfb-0.2.0-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="framebuffer abstraction library, written in C"
+HOMEPAGE="http://www.netsurf-browser.org/projects/libnsfb/"
+SRC_URI="https://download.netsurf-browser.org/libs/releases/${P}-src.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~ppc"
+IUSE="sdl test vnc wayland xcb"
+
+RDEPEND="sdl? ( >=media-libs/libsdl-1.2.15-r4 )
+	vnc? ( >=net-libs/libvncserver-0.9.9-r2 )
+	wayland? ( >=dev-libs/wayland-1.0.6 )
+	xcb? (
+		>=x11-libs/libxcb-1.9.1
+		>=x11-libs/xcb-util-0.3.9-r1
+		>=x11-libs/xcb-util-image-0.3.9-r1
+		>=x11-libs/xcb-util-keysyms-0.3.9-r1
+	)"
+DEPEND="${RDEPEND}
+	dev-util/netsurf-buildsystem"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.1.0-autodetect.patch )
+
+DOCS=( usage )
+
+_emake() {
+	source /usr/share/netsurf-buildsystem/gentoo-helpers.sh
+	netsurf_define_makeconf
+	emake "${NETSURF_MAKECONF[@]}" COMPONENT_TYPE=lib-shared \
+		WITH_VNC=$(usex vnc) \
+		WITH_SDL=$(usex sdl) \
+		WITH_XCB=$(usex xcb) \
+		WITH_WLD=$(usex wayland) \
+		$@
+}
+
+src_compile() {
+	_emake
+}
+
+src_install() {
+	_emake DESTDIR="${ED}" install
+}
diff --git a/dev-libs/libnsfb/libnsfb-0.2.0.ebuild b/dev-libs/libnsfb/libnsfb-0.2.0.ebuild
deleted file mode 100644
index c58a85060137..000000000000
--- a/dev-libs/libnsfb/libnsfb-0.2.0.ebuild
+++ /dev/null
@@ -1,45 +0,0 @@
-# Copyright 1999-2018 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-NETSURF_BUILDSYSTEM=buildsystem-1.7
-inherit netsurf
-
-DESCRIPTION="framebuffer abstraction library, written in C"
-HOMEPAGE="http://www.netsurf-browser.org/projects/libnsfb/"
-
-LICENSE="MIT"
-SLOT="0/${PV}"
-KEYWORDS="~amd64 ~arm ~ppc"
-IUSE="sdl test vnc wayland xcb"
-
-RDEPEND="sdl? ( >=media-libs/libsdl-1.2.15-r4[static-libs?,${MULTILIB_USEDEP}] )
-	vnc? ( >=net-libs/libvncserver-0.9.9-r2[static-libs?,${MULTILIB_USEDEP}] )
-	wayland? ( >=dev-libs/wayland-1.0.6[static-libs?,${MULTILIB_USEDEP}] )
-	xcb? ( >=x11-libs/libxcb-1.9.1[static-libs?,${MULTILIB_USEDEP}]
-		>=x11-libs/xcb-util-0.3.9-r1[static-libs?,${MULTILIB_USEDEP}]
-		>=x11-libs/xcb-util-image-0.3.9-r1[static-libs?,${MULTILIB_USEDEP}]
-		>=x11-libs/xcb-util-keysyms-0.3.9-r1[static-libs?,${MULTILIB_USEDEP}] )"
-DEPEND="${RDEPEND}"
-
-PATCHES=( "${FILESDIR}"/${PN}-0.1.0-autodetect.patch )
-
-DOCS=( usage )
-
-src_prepare() {
-	# working around broken netsurf eclass
-	default
-	multilib_copy_sources
-}
-
-src_configure() {
-	netsurf_src_configure
-
-	netsurf_makeconf+=(
-		WITH_VNC=$(usex vnc)
-		WITH_SDL=$(usex sdl)
-		WITH_XCB=$(usex xcb)
-		WITH_WLD=$(usex wayland)
-	)
-}