# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils toolchain-funcs flag-o-matic

MY_PN="ProFit"
MY_P="${MY_PN}V${PV}"
DESCRIPTION="Designed to be the ultimate protein least squares fitting program"
HOMEPAGE="http://www.bioinf.org.uk/software/profit/"
RESTRICT="fetch"
ORIG_URI="${PN}.tar.gz"
SRC_URI="${P}.tar.gz"
LICENSE="free-noncomm"
SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE="gzip"
RDEPEND=""
DEPEND="${RDEPEND}"
S="${WORKDIR}/${MY_P}"

pkg_nofetch() {
	elog "Download ${ORIG_URI} from ${HOMEPAGE}"
	elog "Rename it to ${SRC_URI} and place it in ${DISTDIR}."
}

src_compile() {
	use gzip && append-flags -DGUNZIP_SUPPORT

	cd src

	emake \
		CC=$(tc-getCC) \
		COPT="${CFLAGS}" \
		|| die "emake failed"
}

src_install() {
	dobin src/${PN}
	insinto /usr/share/${PN}
	doins ProFit.help mdm78.mat

	cat << EOF >> "${T}"/${PN}
HELPDIR="/usr/share/${PN}"
DATADIR="/usr/share/${PN}"
EOF

	newenvd "${T}"/${PN} 50${PN}

	dodoc 00NEW.FEATURES 00Read.Me COPYING.DOC HISTORY INSTALL doc/ProFit.pdf
}