From 922503bc18fad3368180ff17c5302125033deab0 Mon Sep 17 00:00:00 2001
From: Samuli Suominen <ssuominen@gentoo.org>
Date: Fri, 4 Nov 2011 22:37:57 +0000
Subject: Version bump.

(Portage version: 2.2.0_alpha72/cvs/Linux x86_64)
---
 media-libs/libpng/ChangeLog           |  7 ++++-
 media-libs/libpng/libpng-1.5.6.ebuild | 57 +++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+), 1 deletion(-)
 create mode 100644 media-libs/libpng/libpng-1.5.6.ebuild

(limited to 'media-libs/libpng')

diff --git a/media-libs/libpng/ChangeLog b/media-libs/libpng/ChangeLog
index fc91a53c87d5..c139fcaf9d4d 100644
--- a/media-libs/libpng/ChangeLog
+++ b/media-libs/libpng/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libpng
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.326 2011/10/30 18:33:16 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.327 2011/11/04 22:37:57 ssuominen Exp $
+
+*libpng-1.5.6 (04 Nov 2011)
+
+  04 Nov 2011; Samuli Suominen <ssuominen@gentoo.org> +libpng-1.5.6.ebuild:
+  Version bump.
 
   30 Oct 2011; Samuli Suominen <ssuominen@gentoo.org> -libpng-1.4.8-r1.ebuild:
   old
diff --git a/media-libs/libpng/libpng-1.5.6.ebuild b/media-libs/libpng/libpng-1.5.6.ebuild
new file mode 100644
index 000000000000..2224f205633b
--- /dev/null
+++ b/media-libs/libpng/libpng-1.5.6.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.5.6.ebuild,v 1.1 2011/11/04 22:37:57 ssuominen Exp $
+
+# WARNING: media-gfx/optipng is shipping internal copy of libpng14. Look out for
+# security.
+
+EAPI=4
+
+inherit eutils libtool multilib
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? ( mirror://sourceforge/${PN}-apng/${P}-apng.patch.gz )"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="apng static-libs"
+
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}
+	!<x11-libs/gdk-pixbuf-2.24.0-r1
+	!<x11-libs/libsexy-0.1.11-r3
+	!<x11-libs/libview-0.6.6-r2
+	app-arch/xz-utils"
+
+DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
+
+src_prepare() {
+	if use apng; then
+		epatch "${WORKDIR}"/${P}-apng.patch
+		# Don't execute symbols check with apng patch wrt #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+	elibtoolize
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}
+
+pkg_preinst() {
+	has_version ${CATEGORY}/${PN}:1.4 && return 0
+	preserve_old_lib /usr/$(get_libdir)/libpng14$(get_libname 14)
+}
+
+pkg_postinst() {
+	has_version ${CATEGORY}/${PN}:1.4 && return 0
+	preserve_old_lib_notify /usr/$(get_libdir)/libpng14$(get_libname 14)
+}
-- 
cgit v1.2.3-65-gdbad