From c9aaf3ecdcb28d5ca61bdefcc70165d819c91184 Mon Sep 17 00:00:00 2001
From: Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
Date: Fri, 14 May 2010 19:29:43 +0000
Subject: Version bump. (Portage version: HEAD/cvs/Linux x86_64)

---
 dev-python/django/ChangeLog           |   8 ++-
 dev-python/django/django-1.1.2.ebuild | 113 ++++++++++++++++++++++++++++++++++
 2 files changed, 120 insertions(+), 1 deletion(-)
 create mode 100644 dev-python/django/django-1.1.2.ebuild

(limited to 'dev-python')

diff --git a/dev-python/django/ChangeLog b/dev-python/django/ChangeLog
index dacf6957c04a..0a49dac4c8d1 100644
--- a/dev-python/django/ChangeLog
+++ b/dev-python/django/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/django
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/django/ChangeLog,v 1.44 2010/02/14 17:37:11 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/django/ChangeLog,v 1.45 2010/05/14 19:29:43 arfrever Exp $
+
+*django-1.1.2 (14 May 2010)
+
+  14 May 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  +django-1.1.2.ebuild:
+  Version bump.
 
   14 Feb 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
   django-1.1.1.ebuild:
diff --git a/dev-python/django/django-1.1.2.ebuild b/dev-python/django/django-1.1.2.ebuild
new file mode 100644
index 000000000000..273eeb00a145
--- /dev/null
+++ b/dev-python/django/django-1.1.2.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/django/django-1.1.2.ebuild,v 1.1 2010/05/14 19:29:43 arfrever Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+SUPPORT_PYTHON_ABIS="1"
+
+inherit bash-completion distutils webapp
+
+MY_PN="Django"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="High-level python web framework"
+HOMEPAGE="http://www.djangoproject.com/ http://pypi.python.org/pypi/Django"
+SRC_URI="http://pypi.python.org/packages/source/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="doc examples mysql postgres sqlite test"
+
+RDEPEND="dev-python/imaging
+	sqlite? ( || (
+		>=dev-lang/python-2.5[sqlite]
+		( dev-python/pysqlite:2 <dev-lang/python-2.5 )
+	) )
+	postgres? ( dev-python/psycopg )
+	mysql? ( >=dev-python/mysql-python-1.2.1_p2 )"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-python/sphinx-0.3 )
+	test? ( || (
+		>=dev-lang/python-2.5[sqlite]
+		( dev-python/pysqlite:2 <dev-lang/python-2.5 )
+	) )"
+RESTRICT_PYTHON_ABIS="3.*"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS="docs/* AUTHORS"
+WEBAPP_MANUAL_SLOT="yes"
+
+pkg_setup() {
+	webapp_pkg_setup
+}
+
+src_compile() {
+	distutils_src_compile
+
+	if use doc; then
+		pushd docs > /dev/null
+		einfo "Generation of documentation"
+		emake html || die "Generation of documentation failed"
+		popd > /dev/null
+	fi
+}
+
+src_test() {
+	testing() {
+		cat >> tests/settings.py << __EOF__
+DATABASE_ENGINE='sqlite3'
+DATABASE_NAME='test.db'
+ROOT_URLCONF='tests/urls.py'
+SITE_ID=1
+__EOF__
+		# Tests have non-standard assumptions about PYTHONPATH and
+		# don't work with usual "build-${PYTHON_ABI}/lib".
+		PYTHONPATH="." "$(PYTHON)" tests/runtests.py --settings=settings -v1
+	}
+	python_execute_function testing
+}
+
+src_install() {
+	distutils_src_install
+
+	dobashcompletion extras/django_bash_completion
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+
+	if use doc; then
+		mv docs/_build/html/{_,.}sources
+		dohtml txt -r docs/_build/html/*
+	fi
+
+	insinto "${MY_HTDOCSDIR#${EPREFIX}}"
+	doins -r django/contrib/admin/media/* || die "doins failed"
+
+	webapp_src_install
+}
+
+pkg_preinst() {
+	:
+}
+
+pkg_postinst() {
+	bash-completion_pkg_postinst
+	distutils_pkg_postinst
+	einfo "Now, Django has the best of both worlds with Gentoo,"
+	einfo "ease of deployment for production and development."
+	echo
+	elog "A copy of the admin media is available to"
+	elog "webapp-config for installation in a webroot,"
+	elog "as well as the traditional location in python's"
+	elog "site-packages dir for easy development"
+	echo
+	echo
+	ewarn "If you build Django ${PV} without USE=\"vhosts\""
+	ewarn "webapp-config will automatically install the"
+	ewarn "admin media into the localhost webroot."
+}
-- 
cgit v1.2.3-65-gdbad