From 39ed82ca0315883d5d3ae85e57f6ec95f65961a9 Mon Sep 17 00:00:00 2001
From: Alexey Shvetsov <alexxy@gentoo.org>
Date: Sat, 5 May 2012 13:12:09 +0000
Subject: [sys-fs/ocfs2-tools] Version bump. Since 1.6.4 doesnt work with ocfs
 in 3.3+ kernels

(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)
---
 sys-fs/ocfs2-tools/ChangeLog                |  8 ++-
 sys-fs/ocfs2-tools/ocfs2-tools-1.8.2.ebuild | 82 +++++++++++++++++++++++++++++
 2 files changed, 89 insertions(+), 1 deletion(-)
 create mode 100644 sys-fs/ocfs2-tools/ocfs2-tools-1.8.2.ebuild

diff --git a/sys-fs/ocfs2-tools/ChangeLog b/sys-fs/ocfs2-tools/ChangeLog
index 58728890e1eb..e87c8f32ae30 100644
--- a/sys-fs/ocfs2-tools/ChangeLog
+++ b/sys-fs/ocfs2-tools/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/ocfs2-tools
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/ocfs2-tools/ChangeLog,v 1.8 2012/05/05 12:59:48 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/ocfs2-tools/ChangeLog,v 1.9 2012/05/05 13:12:09 alexxy Exp $
+
+*ocfs2-tools-1.8.2 (05 May 2012)
+
+  05 May 2012; Alexey Shvetsov <alexxy@gentoo.org> +ocfs2-tools-1.8.2.ebuild:
+  [sys-fs/ocfs2-tools] Version bump. Since 1.6.4 doesnt work with ocfs in 3.3+
+  kernels
 
   05 May 2012; Alexey Shvetsov <alexxy@gentoo.org>
   +files/ocfs2-tools-recent-kernels.patch, ocfs2-tools-1.6.4-r1.ebuild,
diff --git a/sys-fs/ocfs2-tools/ocfs2-tools-1.8.2.ebuild b/sys-fs/ocfs2-tools/ocfs2-tools-1.8.2.ebuild
new file mode 100644
index 000000000000..63ecd00297ea
--- /dev/null
+++ b/sys-fs/ocfs2-tools/ocfs2-tools-1.8.2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/ocfs2-tools/ocfs2-tools-1.8.2.ebuild,v 1.1 2012/05/05 13:12:09 alexxy Exp $
+
+EAPI=4
+PYTHON_DEPEND="gtk? 2"
+inherit autotools python
+
+# seems like they stopped providing snapshots
+GIT_HASH="db4aef69fa6e9705e17c0b35b9dabc4a41a1d40a"
+
+DESCRIPTION="Support programs for the Oracle Cluster Filesystem 2"
+HOMEPAGE="http://oss.oracle.com/projects/ocfs2-tools/"
+SRC_URI="http://oss.oracle.com/git/?p=ocfs2-tools.git;a=snapshot;h=${GIT_HASH} -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug external gtk"
+
+RDEPEND="
+	sys-apps/util-linux
+	sys-cluster/libcman
+	external? (
+		sys-cluster/libdlm
+		<sys-cluster/pacemaker-1.1[-heartbeat]
+		)
+	sys-fs/e2fsprogs
+	sys-libs/ncurses
+	sys-libs/readline
+	sys-process/psmisc
+	gtk? (
+		dev-python/pygtk
+	)
+"
+# 99% of deps this thing has is automagic
+# specialy cluster things corosync/pacemaker
+DEPEND="${RDEPEND}"
+
+DOCS=(
+	"${S}/documentation/samples/cluster.conf"
+	"${S}/documentation/users_guide.txt"
+)
+
+MAKEOPTS+=" -j1"
+
+PATCHES=(
+		"${FILESDIR}/${PN}-1.6.4-asneeded.patch"
+		"${FILESDIR}/${PN}-recent-kernels.patch"
+		)
+
+S="${WORKDIR}/${PN}.git"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	# gentoo uses /sys/kernel/dlm as dlmfs mountpoint
+	sed -e 's:"/dlm/":"/sys/kernel/dlm":g' \
+		-i libo2dlm/o2dlm_test.c \
+		-i libocfs2/dlm.c || die "sed failed"
+	epatch ${PATCHES[@]}
+	rm -f aclocal.m4
+	AT_M4DIR=. eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug debug) \
+		$(use_enable debug debugexe) \
+		$(use_enable gtk ocfs2console) \
+		--enable-dynamic-fsck \
+		--enable-dynamic-ctl
+}
+
+src_install() {
+	default
+	newinitd "${FILESDIR}/ocfs2.initd" ocfs2
+	newconfd "${FILESDIR}/ocfs2.confd" ocfs2
+}
-- 
cgit v1.2.3-65-gdbad