KDE 3.5.0 (not yet released, p.masked)

(Portage version: 2.0.53_rc7)

1 files changed, 62 insertions, 0 deletions

diff --git a/kde-base/kdenetwork/kdenetwork-3.5.0.ebuild b/kde-base/kdenetwork/kdenetwork-3.5.0.ebuild
new file mode 100644
index 000000000000..494198ef3b29
--- /dev/null
+++ b/kde-base/kdenetwork/kdenetwork-3.5.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdenetwork/kdenetwork-3.5.0.ebuild,v 1.1 2005/11/22 22:14:03 danarmak Exp $
+
+inherit kde-dist eutils
+
+DESCRIPTION="KDE network apps: kopete, kppp, kget..."
+
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="rdesktop sametime slp ssl wifi xmms"
+
+DEPEND="~kde-base/kdebase-${PV}
+	dev-libs/libxslt
+	dev-libs/libxml2
+	net-dns/libidn
+	>=dev-libs/glib-2
+	sametime? ( =net-libs/meanwhile-0.4* )
+	slp? ( net-libs/openslp )
+	wifi? ( net-wireless/wireless-tools )
+	xmms? ( media-sound/xmms )"
+# glib: for webcam support in Kopete.
+
+RDEPEND="${DEPEND}
+	rdesktop? ( >=net-misc/rdesktop-1.4.1 )
+	dev-lang/perl
+	ssl? ( app-crypt/qca-tls
+	       dev-perl/IO-Socket-SSL )"
+# perl: for KSirc.
+# qca-tls: for Kopete jabber plugin.
+# IO-Socket-SSL: for SSL support in KSirc.
+
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+src_compile() {
+	local myconf="--with-libidn
+	              $(use_enable sametime sametime-plugin)
+	              $(use_enable slp) $(use_with wifi)
+	              $(use_with xmms) --without-external-libgadu"
+
+	kde_src_compile
+}
+
+src_install() {
+	kde_src_install
+
+	chmod u+s ${D}/${KDEDIR}/bin/reslisa
+
+	# empty config file needed for lisa to work with default settings
+	dodir /etc
+	touch ${D}/etc/lisarc
+
+	# lisa, reslisa initscripts
+	sed -e "s:_KDEDIR_:${KDEDIR}:g" ${FILESDIR}/lisa > ${T}/lisa
+	sed -e "s:_KDEDIR_:${KDEDIR}:g" ${FILESDIR}/reslisa > ${T}/reslisa
+	exeinto /etc/init.d
+	doexe ${T}/lisa ${T}/reslisa
+
+	insinto /etc/conf.d
+	newins ${FILESDIR}/lisa.conf lisa
+	newins ${FILESDIR}/reslisa.conf reslisa
+}